如何在 Unity 中设置整个颜色通道的饱和度

Question

我想在主相机中设置整个颜色通道的饱和度。我发现的最接近的选项是色调与饱和度分级曲线。场景的背景是一棵青色的棕榈树。我希望树的绿色程度仍然显示。与前景中的草顶相同，它比绿色更接近黄色，但我仍然想看到它具有的一点绿色值。

几周来我一直在 Unity 文档和资源商店中搜索可能的第三方着色器，但一无所获。我目前的结果是我能想到的最好的结果，任何帮助将不胜感激。谢谢

已解决 - 通过复选标记的答案。只是想与将来偶然发现此问题的任何人分享结果。将上面的屏幕截图与下面的屏幕截图进行比较，其中背景中的棕榈树和前景中的草顶都是黑白的。完全掌控场景中的RGB饱和度！

Answer 1

使用此方法的示例：

下面是一个后处理着色器，旨在让您设置每个颜色通道的饱和度。

它首先获取原始像素颜色，获取色调、饱和度和亮度。该颜色被采用为最饱和、中性亮度的版本。然后将其 rgb 乘以去饱和因子以计算新色调的 rgb。该 RGB 的大小乘以原始饱和度即可得到新的饱和度。这种新的色调和饱和度与原始亮度一起反馈以计算新的颜色。

Shader "Custom/ChannelSaturation" {
    Properties{
        _MainTex("Base", 2D) = "white" {}
        _rSat("Red Saturation", Range(0, 1)) = 1
        _gSat("Green Saturation", Range(0, 1)) = 1
        _bSat("Blue Saturation", Range(0, 1)) = 1
    }
        SubShader{
            Pass {
                CGPROGRAM
                #pragma vertex vert_img
                #pragma fragment frag
                #include "UnityCG.cginc"

                uniform sampler2D _MainTex;
                float _rSat;
                float _gSat;
                float _bSat;

                /*
                  source: modified version of https://www.shadertoy.com/view/MsKGRW
                  written @ https://gist.github.com/hiroakioishi/
                            c4eda57c29ae7b2912c4809087d5ffd0
                */
                float3 rgb2hsl(float3 c) {
                    float epsilon = 0.00000001;
                    float cmin = min( c.r, min( c.g, c.b ) );
                    float cmax = max( c.r, max( c.g, c.b ) );
                    float cd   = cmax - cmin;
                    float3 hsl = float3(0.0, 0.0, 0.0);
                    hsl.z = (cmax + cmin) / 2.0;
                    hsl.y = lerp(cd / (cmax + cmin + epsilon), 
                            cd / (epsilon + 2.0 - (cmax + cmin)), 
                            step(0.5, hsl.z));

                    float3 a = float3(1.0 - step(epsilon, abs(cmax - c)));
                    a = lerp(float3(a.x, 0.0, a.z), a, step(0.5, 2.0 - a.x - a.y));
                    a = lerp(float3(a.x, a.y, 0.0), a, step(0.5, 2.0 - a.x - a.z));
                    a = lerp(float3(a.x, a.y, 0.0), a, step(0.5, 2.0 - a.y - a.z));
    
                    hsl.x = dot( float3(0.0, 2.0, 4.0) + ((c.gbr - c.brg) 
                            / (epsilon + cd)), a );
                    hsl.x = (hsl.x + (1.0 - step(0.0, hsl.x) ) * 6.0 ) / 6.0;
                    return hsl;
                }

                /*
                  source: modified version of
                          https://stackoverflow.com/a/42261473/1092820
                */
                float3 hsl2rgb(float3 c) {
                    float3 rgb = clamp(abs(fmod(c.x * 6.0 + float3(0.0, 4.0, 2.0),
                            6.0) - 3.0) - 1.0, 0.0, 1.0);
                    return c.z + c.y * (rgb - 0.5) * (1.0 - abs(2.0 * c.z - 1.0));
                }

                float4 frag(v2f_img i) : COLOR {
                    float3 sat = float3(_rSat, _gSat, _bSat);

                    float4 c = tex2D(_MainTex, i.uv);
                    float3 hslOrig = rgb2hsl(c.rgb);

                    float3 rgbFullSat = hsl2rgb(float3(hslOrig.x, 1, .5));
                    float3 diminishedrgb = rgbFullSat * sat;

                    float diminishedHue = rgb2hsl(diminishedrgb).x;

                    float diminishedSat = hslOrig.y * length(diminishedrgb);
                    float3 mix = float3(diminishedHue, diminishedSat, hslOrig.z);
                    float3 newc = hsl2rgb(mix);

                    float4 result = c;
                    result.rgb = newc;

                    return result;
                }
                ENDCG
            }
        }
}

如果您使用推荐的 URP（通用渲染管道），您可以创建一个新的前向渲染器管道资源，将着色器分配给该资源，并进行适当的配置。包括图表在内的更多信息可以在URP 自定义渲染通道的官方 Unity 教程中找到。

如果您不使用 URP，您还有其他选择。您可以将其附加到特定材质，或使用Wikibooks中的以下脚本到相机的游戏对象，以使用上述着色器将材质应用为相机的后处理效果：

using System;
using UnityEngine;

[RequireComponent(typeof(Camera))]
[ExecuteInEditMode]

public class PostProcessingEffectScript : MonoBehaviour {

   public Material material;
   
   void OnEnable() 
   {
      if (null == material || null == material.shader || 
         !material.shader.isSupported)
      {
         enabled = false;
      } 
   }

   void OnRenderImage(RenderTexture source, RenderTexture destination)
   {
      Graphics.Blit(source, destination, material);
   }
}

如果您使用后处理效果，您将需要使用不同的相机渲染要从效果中排除的内容，然后将所有内容放在一起。然而，这有点超出了这个答案的范围。