如何动态导入zig模块？

Question

我正在使用 Zig 0.7.0.，并尝试从数组导入 Zig 源文件列表。每个源文件都有一个我想调用的main函数（其返回类型为）。!void该数组module_names在编译时是已知的。

这是我尝试做的：

const std = @import("std");
const log = std.log;

const module_names = [_][]const u8{
    "01.zig", "02.zig", "03.zig", "04.zig", "05.zig",
};

pub fn main() void {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    for (module_names) |module_name, i| {
        const module = @import(module_name); // this fails
        log.info("i {}", .{i});
        try module.main();
    }
}

即使数组在编译时已知，@import(module_name)也会出现以下错误：

./src/main.zig:13:32: error: unable to evaluate constant expression
        const module = @import(module_name);
                               ^
./src/main.zig:13:24: note: referenced here
        const module = @import(module_name);

如果数组是动态生成的并且仅在运行时已知，我可以理解错误，但这里数组module_names在编译时已知。所以我有点困惑...

或者，我也尝试将整个main主体包裹在一个comptime块中：

pub fn main() void {
    comptime {
        var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
        defer arena.deinit();

        for (module_names) |module_name, i| {
            const module = @import(module_name); // no errors here
            log.info("i {}", .{i});
            try module.main();
        }
    }
}

这里@import(module_name)没有给我任何错误，但是log.info失败并出现其他错误：

/home/jack/.zig/lib/zig/std/mutex.zig:59:87: error: unable to evaluate constant expression
            if (@cmpxchgWeak(usize, &self.state, 0, MUTEX_LOCK, .Acquire, .Monotonic) != null)
                                                                                      ^
/home/jack/.zig/lib/zig/std/mutex.zig:65:35: note: called from here
            return self.tryAcquire() orelse {
                                  ^
/home/jack/.zig/lib/zig/std/log.zig:145:60: note: called from here
            const held = std.debug.getStderrMutex().acquire();
                                                           ^
/home/jack/.zig/lib/zig/std/log.zig:222:16: note: called from here
            log(.info, scope, format, args);
               ^
./src/main.zig:26:21: note: called from here
            log.info("i {}", .{i});

zig 中可以实现这种动态导入吗？

Answer 1

从Zig 0.8.0开始，操作数 to@import必须是字符串文字。

Zig 编译器想要知道所有可能导入的文件，以便在您启动编译过程时它可以急切地找到它们并编译它们。该语言的设计受到快速编译器存在的限制。

所以，我们能做些什么？我认为这以等效的方式完成任务：

const std = @import("std");
const log = std.log;

const modules = struct {
    pub const module_01 = @import("01.zig");
    pub const module_02 = @import("02.zig");
    pub const module_03 = @import("03.zig");
    pub const module_04 = @import("04.zig");
    pub const module_05 = @import("05.zig");
};

pub fn main() void {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    inline for (@typeInfo(modules).Struct.decls) |decl, i| {
        const module = @field(modules, decl.name);
        log.info("i {d}", .{i});
        try module.main();
    }
}

事实上，这里的巧妙之处在于，编译器能够急切地获取所有 5 个文件并启动编译过程，甚至在运行编译时代码以确定实际导入哪个文件之前也是如此。双赢。

Answer 2

我认为您所追求的导入是可能的，我的理解是@import获取zig源文件并将其转换为结构类型。它实际上似乎甚至可以在运行时完成（尽管不使用@import，它需要一个comptime参数（这是您的问题的重要部分）。

您的第一个示例失败的原因是您传递的参数module_name在 处未知comptime，for在程序运行之前您的循环不会执行。

您解决问题的直觉是正确的，让循环在编译时进行评估（特别是捕获值和迭代器）；我认为你可以做两件事来解决它。

像您所做的那样将循环包装在comptime块中是可行的，但是您需要考虑在编译时计算表达式的确切含义，以及它是否有意义。我认为 的实现log将阻止您在编译时进行日志记录，因此您需要在循环内收集您感兴趣的值，并在块外将它们记录一次comptime。

修复此问题的另一种方法是通过使用内联 for展开循环来强制在编译时评估循环的捕获值：

pub fn main() !void {
    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();

    inline for (module_names) |module_name, i| {
        const module = @import(module_name);
        log.info("i {}", .{i});
        try module.main();
    }
}

免责声明：可能有更好的方法来做到这一点，我对这门语言比较陌生=D