EXCEL VBA - 如果目录和文件夹不存在，则创建它们

Question

我在 A 列中有一个文件夹位置列表，它定义了我要创建的目录层次结构（例如“C:\topFolder\nextFolder\lastFolder\”）。代码运行没有错误，但没有创建文件夹。我是什么这里做错了吗？

Sub newDestination()
    Dim Path As Variant
    Dim folderLevel As Variant

    For Each Path In Sheet11.Range("A:A")
        For Each folderLevel In Split(Path.Value, "\")
            folderLevel = folderLevel & "\"
            If Len(Dir(folderLevel, vbDirectory)) = 0 Then
                MkDir folderLevel
            End If
        Next folderLevel
    Next Path

End Sub

Answer 1

您正在创建孤立文件夹。mkdir "abc\" 将在 WorkBook 的目录中创建一个名为 abc 的文件夹。如果未保存工作簿，则会在 MyDocuments 中创建此文件夹（最相似，取决于 Excel 的配置）。

您需要传递完全合格的路径以在您想要的位置创建一个文件夹，例如“C:\Temp\abc\”

在您的代码中，问题在于您如何运行 for 循环并传递文件夹名称。

这是您需要执行此操作的方式：

Sub test()

    Dim strPath  As String
    Dim lCtr     As Long

    strPath = "C:\Temp\Parent\Child\ChildsChild"

    arrpath = Split(strPath, "\")
    strPath = arrpath(LBound(arrpath)) & "\"

    For lCtr = LBound(arrpath) + 1 To UBound(arrpath)
        strPath = strPath & arrpath(lCtr) & "\"            
        If Dir(strPath, vbDirectory) = "" Then
            MkDir strPath
        End If
    Next

End Sub