在VBA中使用VLookup引用另一个Excel文件

Question

我正在尝试在 VBA 中编写一个引用另一个文件的 VLookup 表。这是我的目标的简单概述：

• 在另一个 Excel 文件中查找单元格 A2 中的值
• 从另一个 Excel 文件的第 2 列中提取信息并将其放置在单元格 B2 中
• 移至单元格 A3 并重复该过程，直到 A 列中不再有任何条目

这是我已经拥有的代码。我不断收到错误消息“无法获取 WOrksheetFunction 类的 VLookup 属性”。我检查了引用该错误的其他帖子，但它们没有任何帮助。大家看到我的代码有错误吗？或者有谁有更好的方法来完成这项任务？

Sub SBEPlannerAdder()

Dim wbk As Workbook
Set wbk = Workbooks.Open("C:\Users\user\Documents\Support File\Planner.xlsx")

With Sheets("Sheet1")

    ' Selects the first cell to check
    Range("A2").Select
    Dim x As Variant
    x = wbk.Worksheets("Sheet1").Range("A1:C1752")

    ' Loops through all rows until an empty row is found
    Do Until IsEmpty(ActiveCell)

        Range(ActiveCell.Offset(0, 1) & ActiveCell.Row).Value = Application.WorksheetFunction.VLookup((ActiveCell.Column & ActiveCell.Row), x, 2, 0)
        ActiveCell.Offset(1, 0).Select
    Loop
End With

Call wbk.Close(False)
End Sub

Answer 1

当您打开工作簿时，它将成为活动工作簿。看来您从未将控制权传递回目标工作簿。

Sub SBEPlannerAdder()
    Dim rw As Long, x As Range
    Dim extwbk As Workbook, twb As Workbook

    Set twb = ThisWorkbook
    Set extwbk = Workbooks.Open("C:\Users\user\Documents\Support File\Planner.xlsx")
    Set x = extwbk.Worksheets("Sheet1").Range("A1:C1752")

    With twb.Sheets("Sheet1")

        For rw = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
            .Cells(rw, 2) = Application.VLookup(.Cells(rw, 1).Value2, x, 2, False)
        Next rw

    End With

    extwbk.Close savechanges:=False
End Sub

请参阅如何避免在 Excel VBA 宏中使用 Select，了解摆脱依赖 select 和 activate 来实现目标的更多方法。