递归匿名函数计算序列总和

Question

我尝试编写一个函数来计算以下内容，

我能想出的就是这个，这是行不通的。

$fact = sub {
    $n = shift;
    if($n==0 || $n ==1){
        return 1;
    }else{
        return $n*&$fact($n-1);
    }
}

sub fun{
    ($x,$n)= @_;
    if($n==0){
        return 1;
    }elsif($n == 1){
        return $x;
    }else{
        return ($x)/&$fact($n)+fun($x,$n-1);
    }
}



print (fun(3,5));

Answer 1

首先，始终使用

use strict;
use warnings qw( all );

它会发现你的错误之一。

其次，你错误地命名了你的 sub，你错过了一个my，并且你发明了一个特殊情况 (since ($x**1)/1! == $x) ^[1]。现在忽略使其匿名的需要f很简单：

sub f {
   my ($x, $n) = @_;
   return 1 if $n == 0;
   return ($x**$n) / fact($x) + f($x, $n-1);
}

同样，fact简单来说就是：

sub fact {
   my ($n) = @_;
   my $acc = 1;
   $acc *= $_ for 1..$n;
   return $acc;
}

就问题而言，使递归函数匿名只是将递归调用替换为__SUB__->(...)^[2]的问题，因此以下是匿名版本：

use feature qw( current_sub );

my $f = sub {
   my ($x, $n) = @_;
   return 1 if $n == 0;
   return ($x**$n) / fact($x) + __SUB__->($x, $n-1);
};

如果你fact也想匿名

use feature qw( current_sub );

my $f = sub {
   my ($x, $n) = @_;
   return 1 if $n == 0;

   my $fact = sub {
      my ($n) = @_;
      my $acc = 1;
      $acc *= $_ for 1..$n;
      return $acc;
   };

   return ($x**$n) / $fact->($x) + __SUB__->($x, $n-1);
};

也就是说，使用递归对于这个函数来说是一种巨大的浪费。这是一个有效的实现：

my $f = sub {
   my ($x, $n) = @_;

   my $acc             = 1;
   my $numerator_acc   = 1;
   my $denominator_acc = 1;
   for (1..$n) {
      $numerator_acc   *= $x;
      $denominator_acc *= $_;
      $acc += ( $numerator_acc / $denominator_acc );
   }

   return $acc;
};

1. 从技术上讲，你发明了两个($x**0)/0! == 1，但$n == 0无论如何都必须在某种程度上进行特殊对待。

2. __SUB__在 Perl 5.16 中引入。在此之前，如果你想避免内存泄漏，情况会更复杂。