我可以从缓冲区(pByte)和大小创建VarArray OleVariant而无需复制吗？

Question

我可以将内存从缓冲区复制到安全数组中,如下所示

  function GetVarArrayFromBuffer(ABuffer : pByte; ASizeInBytes: Cardinal) : OleVariant;
  var
    LVarArrayPtr: Pointer;     
  begin
    Result := VarArrayCreate([0, ASizeInBytes - 1], varByte);
    LVarArrayPtr := VarArrayLock(Result);
    try
      Move(ABuffer^, LVarArrayPtr^, ASizeInBytes);
    finally
      VarArrayUnLock(Result);
    end;
  end;

但是,有没有办法直接将我的指针和大小传递到一个varArray类型OleVariant而不复制内存？

[编辑]

我可以看到里面的数组OleVariant是a SAFEARRAY(定义为PVarArray = ^TVarArray),所以看起来应该有一种方法可以通过填充a中的值TVarArray并设置VType和中的VArray值来实现OleVariant.

Answer 1

有没有办法直接将我的指针和大小传递到varArray类型OleVariant而不复制内存？

Delphi的OleVariant类型是OLE VARIANT记录的包装器.OLE支持的唯一类型的数组是SAFEARRAY,并且SAFEARRAY由Win32 SafeArrayCreate...()函数创建的任何数组都分配并拥有它指向的数据块.您必须将源数据复制到该块中.

要绕过它,你必须跳过VarArrayCreate()(调用SafeArrayCreate())并SAFEARRAY自己分配,SafeArrayAllocDescriptor/Ex()这样它就不会分配数据块.然后,您可以将数组的pvData字段设置为指向现有内存块,并FADF_AUTO在其fFeatures字段中启用该标志以告知SafeArrayDestroy()(OleVariant当不再需要时调用哪些调用SAFEARRAY)不释放内存块.

尝试这样的事情:

uses
  ..., Ole2, ComObj;

// Delphi's Ole2 unit declares SafeArrayAllocDescriptor()
// but does not declare SafeArrayAllocDescriptorEx()...
function SafeArrayAllocDescriptorEx(vt: TVarType; cDims: Integer; var psaOut: PSafeArray): HResult; stdcall; external 'oleaut32.dll';

function GetVarArrayFromBuffer(ABuffer : pByte; ASizeInBytes: Cardinal) : OleVariant;
var
  SA: PSafeArray;
begin
  OleCheck(SafeArrayAllocDescriptorEx(VT_UI1, 1, SA)); 

  SA.fFeatures := SA.fFeatures or FADF_AUTO or FADF_FIXEDSIZE;
  SA.cbElements := SizeOf(Byte);
  SA.pvData := ABuffer;
  SA.rgsabound[0].lLbound := 0;
  SA.rgsabound[0].cElements := ASizeInBytes;

  TVarData(Result).VType := varByte or varArray;
  TVarData(Result).VArray := PVarArray(SA);
end;

如果您实际上不需要使用OLE,例如,如果您没有通过OLE将数组传递给其他人的应用程序,那么您应该使用Delphi的Variant类型.您可以编写一个Custom Variant Type来保存您想要的任何数据,甚至是对现有内存块的引用,然后Variant根据需要使用,并让您的自定义类型实现根据需要管理数据.