在一个脚本中加入多个 sed 命令以处理 CSV 文件

Question

有一个像这样的 CSV 文件：

HEADER
"first, column"|"second "some random quotes" column"|"third ol' column"
FOOTER

并寻找类似的结果：

HEADER
first, column|second "some random quotes" column|third ol' column

换句话说，删除“FOOTER”、开头、结尾和周围的引号 |。

到目前为止，这段代码有效：

sed '/FOOTER/d' csv > csv1 | #remove FOOTER
sed 's/^\"//' csv1 > csv2 | #remove quote at the beginning
sed 's/\"$//' csv2 > csv3 | #remove quote at the end
sed 's/\"|\"/|/g' csv3 > csv4 #remove quotes around pipe

如您所见，问题在于它创建了 4 个额外的文件。

这是另一个解决方案，其目标是不创建额外的文件并在单个脚本中执行相同的操作。它不能很好地工作。

#!/bin/ksh

sed '/begin/, /end/ { 
        /FOOTER/d
        s/^\"//
        s/\"$//
        s/\"|\"/|/g 
}' csv > csv4

Answer 1

首先，正如迈克尔所展示的，您可以将所有这些组合成一个命令：

sed '/^FOOTER/d; s/^\"//; s/\"$//; s/\"|\"/|/g' csv > csv1

我认为某些sed实现无法应对，可能需要：

  sed -e '/^FOOTER/d' -e 's/^\"//' -e 's/\"$//' -e 's/\"|\"/|/g' csv > csv1

也就是说，看起来您的字段是由定义的，|并且您只想删除"整个字段，留下字段内的那些。在这种情况下，你可以这样做：

$ sed '/FOOTER/d; s/\(^\||\)"/\1/g; s/"\($\||\)/\1/g' csv 
HEADER
first, column|second "some random quotes" column|third ol' column

或者，使用 GNU sed：

sed -r '/FOOTER/d; s/(^|\|)"/\1/g; s/"($|\|)/\1/g' csv 

你也可以使用 Perl：

$ perl -F"|" -lane 'next if /FOOTER/; s/^"|"$// for @F; print @F' csv 
HEADER
first, column|second some random quotes column|third ol' column

Answer 2

这也可以：

sed 's/^"//; s/"|"/|/g; s/""$/"/'

例子：

$ echo '"this"|" and "ths""|" and "|" this 2"|" also "this", "thi", "and th""' | 
sed 's/^"//; s/"|"/|/g; s/""$/"/'
this| and "ths"| and | this 2| also "this", "thi", "and th"

漂亮的版本

sed '
s/^"//
s/"|"/|/g
s/""$/"/
$d
'