如何使用TIdIMAP4登录Gmail帐户并获取邮箱中的邮件数量？

Question

如何登录Gmail帐户并获取INBOX包含TIdIMAP4组件的邮箱中的邮件数？

Answer 1

要获取Gmail收件箱中的邮件总数,您需要先使用凭据连接到Gmail IMAP服务器,然后选择Gmail的收件箱邮箱,并为该选定的邮箱读取该TotalMsgs属性的值.

在代码中它可能如下所示(此代码需要OpenSSL,因此不要忘记将libeay32.dll和ssleay32.dll库放在项目可见的路径中;您可以在不同版本和平台下载Indy的OpenSSL库from here):

uses
  IdIMAP4, IdSSLOpenSSL, IdExplicitTLSClientServerBase;

function GetGmailMessageCount(const UserName, Password: string): Integer;
var
  IMAPClient: TIdIMAP4;
  OpenSSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  Result := 0;
  IMAPClient := TIdIMAP4.Create(nil);
  try
    OpenSSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
    try
      OpenSSLHandler.SSLOptions.Method := sslvSSLv3;
      IMAPClient.IOHandler := OpenSSLHandler;
      IMAPClient.Host := 'imap.gmail.com';
      IMAPClient.Port := 993;
      IMAPClient.UseTLS := utUseImplicitTLS;
      IMAPClient.Username := UserName;
      IMAPClient.Password := Password;
      IMAPClient.Connect;
      try
        if IMAPClient.SelectMailBox('INBOX') then
          Result := IMAPClient.MailBox.TotalMsgs;
      finally
        IMAPClient.Disconnect;
      end;
    finally
      OpenSSLHandler.Free;
    end;
  finally
    IMAPClient.Free;
  end;
end;

procedure TForm1.ConnectButtonClick(Sender: TObject);
begin
  ShowMessage('Total count of messages in inbox: ' +
    IntToStr(GetGmailMessageCount('UserName@gmail.com', 'Password')));
end;

您可以选择下载demo project包含OpenSSL v1.0.1c用于32位应用程序的i386平台的库(在Delphi 2009中编译).