跨行拆分单行

Question

给定一个Promotion包含行和数据的表,例如:

PromotionId    Codes
1              a,b
2              c
3              d,e,f

我怎么能写一个查询来返回它像这样:

PromotionId    Codes
1              a
1              b
2              c
3              d
3              e
3              f

基本上我想将代码字符串拆分成多行.

Answer 1

您可以使用Split表值函数,例如:

CREATE FUNCTION [dbo].[Split]
(
    @ItemList NVARCHAR(MAX), 
    @delimiter CHAR(1)
)
RETURNS @IDTable TABLE (Item VARCHAR(50))  
AS      

BEGIN    
    DECLARE @tempItemList NVARCHAR(MAX)
    SET @tempItemList = @ItemList

    DECLARE @i INT    
    DECLARE @Item NVARCHAR(4000)

    SET @tempItemList = REPLACE (@tempItemList, ' ', '')
    SET @i = CHARINDEX(@delimiter, @tempItemList)

    WHILE (LEN(@tempItemList) > 0)
    BEGIN
        IF @i = 0
            SET @Item = @tempItemList
        ELSE
            SET @Item = LEFT(@tempItemList, @i - 1)
        INSERT INTO @IDTable(Item) VALUES(@Item)
        IF @i = 0
            SET @tempItemList = ''
        ELSE
            SET @tempItemList = RIGHT(@tempItemList, LEN(@tempItemList) - @i)
        SET @i = CHARINDEX(@delimiter, @tempItemList)
    END 
    RETURN
END  

然后你可以CROSS APPLY用来加入它:

SELECT PromotionId, CodeList.Item AS Codes
FROM Promotion p
    CROSS APPLY dbo.Split(Codes, ',') CodeList

编辑:这里有你的数据:http : //sqlfiddle.com/#!3/85f8b/1/0

结果:

PROMOTIONID    CODES
  1             a
  1             b
  2             c
  3             d
  3             e
  3             f