当命令类型是adCmdText时,是否可以使用命名参数？

Question

我正在尝试通过Adodb.Command使用以下查询命名参数,但没有运气.

Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1

代码我使用了类似的东西.

Dim cmd
Set cmd = Server.CreateObject("Adodb.Command")
cmd.NamedParameters = True
cmd.CommandType = adCmdText
cmd.CommandText = "Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1"
cmd.Parameters.Append cmd.CreateParameter("@param1", adVarchar, adParamInput, 20, "some text 1")
cmd.Parameters.Append cmd.CreateParameter("@param2", adVarchar, adParamInput, 20, "some text 2")
Set cmd.ActiveConnection = cn
Dim rs
Set rs = cmd.Execute

问题是,这会导致RDBMS端出错.

Microsoft OLE DB Provider for SQL Server error '80040e14' 

Must declare the scalar variable "@param1".

如果查询是存储过程调用,则没有任何问题.所以,我猜namedparameters仅影响调用存储过程的命令对象.当我使用SQL Server Profiler跟踪查询时,我看到只运行了以下查询(请注意,没有参数声明,没有值赋值).

SQL:BatchStarting   Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2)
SQL:BatchCompleted  Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2)

但是我需要在本机不同的查询上执行此操作.我怎么能这样做,没有字符串连接等的最佳做法是什么.我不想用问号准备查询,我不喜欢用顺序传递参数(它是必要的问号而没有命名参数)多次.任何帮助将不胜感激.

关于误解的更新:我正在寻找一种不依赖于数据库的通用解决方案.

Answer 1

您不能在OLE DB中将命名参数与ad-hoc查询一起使用.如果您使用的是SQL Server,则可以执行以下操作:

Dim sql
sql = ""
sql = sql & "DECLARE @param1 varchar(20) = ?;"
sql = sql & "DECLARE @param2 varchar(20) = ?;"
sql = sql & "Select * From mytable Where col1 = Lower(@param1) And col2 = Upper(@param2) And col3 = @param1;"

' This section is basically the same as in the original question
Dim cmd
Set cmd = Server.CreateObject("Adodb.Command")
cmd.CommandType = adCmdText
cmd.CommandText = sql
cmd.Parameters.Append cmd.CreateParameter("@param1", adVarchar, adParamInput, 20, "some text 1")
cmd.Parameters.Append cmd.CreateParameter("@param2", adVarchar, adParamInput, 20, "some text 2")
Set cmd.ActiveConnection = cn
Dim rs
Set rs = cmd.Execute

您仍然需要按位置绑定参数,但这样,更容易看到正确的顺序,您可以在多个位置使用相同的参数.