尝试使用WMI将文件从一台XP PC复制到另一台PC,因为RPC和UNC不可用

Question

尝试使用WMI将文件从一台XP PC复制到另一台PC,因为RPC和UNC不可用

我是VBScript的新手.我找不到使用VBS中的WMI将文件从一个XP主机复制到另一个主机的方法.复制文件的常用方法(RPC - 远程过程调用,SMB,UNC)不可用于多个主机,但WMI可供所有主机使用,我需要将文件从管理主机复制到目标Windows主机.我以为我会找到一些示例代码,但我没有找到相关信息.没有找到任何告诉我也无法做到的事情.

源文件是我的管理员计算机的'F:\ TEMP'文件夹中的可执行文件和'test1.txt'.我想把文件放在远程主机HOST1的'C:\ TEMP'文件夹中.我拥有两台主机的完全管理员权限.这是我到目前为止,只为一个文件(以保持测试简单):

strComputer = "HOST1"
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colFiles = objWMIService.ExecQuery( _
    "Select * from Win32_Directory where Name = 'c:\\temp'")
For Each objFiles in colFiles
    errResults  = objFolder.Copy("f:\temp\test1.txt")
    Wscript.Echo errResults
Next

Run Code Online (Sandbox Code Playgroud)

Answer 1

Liz*_*izz 6

我了解到WMI无法在远程主机上创建文件,也无法通过网络连接复制文件:http: //msdn.microsoft.com/en-us/library/windows/desktop/aa389288%28v=vs.85% 29.aspx

但是,它可以运行cmd进程.这是Frank White在C sharp中的代码,接着是他的例子:https: //stackoverflow.com/a/8913231/1569434

InputParameters("CommandLine") = "cmd /c echo myFTPCommands > c:\ftpscript.txt"

Run Code Online (Sandbox Code Playgroud)

您将需要四件事来使用以下所有scriptlet,它们相互构建以使用psexec在远程主机上运行"普通"VBScript或批处理脚本:

远程主机上的管理员权限;
在远程主机上启用了WMI
远程主机可以访问的网络共享(使用RPC,UNC,FTP等,但不是 DFS!("分布式文件系统" - 请参阅注释);以及
psexec.exe和网络共享上的"普通"脚本.

重要提示:请不要使用DFS来映射网络共享!如果您将分布式文件系统用于网络共享,则会失败.根据您的尝试方式,您可能获得的错误代码是"系统错误1312",无论您使用哪种操作系统(例如,XP,Win 7).

当RPC在远程主机上不可用但WMI不可用时,以下方法将在远程主机的c:\ temp文件夹上创建一个本地ASCII文件,其中包含文本"myTextCommands",不带引号.

' https://stackoverflow.com/questions/8884728/wmi-remote-process-to-copy-file
strCommand = "cmd /c echo myTextCommands > c:\temp\testscript.txt"
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" _
    & strComputer & "\root\cimv2")
Set objProcess = objWMIService.Get("Win32_Process")
errReturn = objProcess.Create(strCommand, null, null, intProcessID)
' See following link for error codes returned by errReturn
' http://msdn.microsoft.com/en-us/library/windows/desktop/aa389388(v=vs.85).aspx

Run Code Online (Sandbox Code Playgroud)

请注意上面脚本中的重要限制:它只能创建ASCII文件 - 而不是二进制文件.

让我们使用该技术来映射驱动器号:

strCommand = "cmd /c net use z: " & MyShare & " /user:%USERDOMAIN%\%USERNAME% " _
    & strPassword & ">" & strRemoteLog
Set objProcess = objWMIService.Get("Win32_Process")
Call errProcess

Run Code Online (Sandbox Code Playgroud)

其中"strRemoteLog"设置为"c:\ temp\MyLog.txt",提示"strPassword"(参见底部的完整脚本示例和参考),"errProcess"是使用以下过程运行以下过程的子例程上面提到的"cmd/c"技巧:

Sub errProcess
errReturn = objProcess.Create(strCommand, null, null, intProcessID)
If errReturn = 0 Then
    Wscript.Echo "Process was started with a process ID: " & intProcessID
    WScript.Sleep 5000
Else
    Wscript.Echo "Process could not be started due to error: " & errReturn
End If
End Sub

Run Code Online (Sandbox Code Playgroud)

映射网络驱动器后,将脚本复制到主机:

strCommand="cmd /c xcopy Z:\scripts\SCRIPT1.bat c:\temp\ >>" & strRemoteLog
Call errProcess

Run Code Online (Sandbox Code Playgroud)

SCRIPT1.bat准备好了,所以在远程主机上对它启动psexec,向你的脚本传递一个先前可以获得的变量strUserID,例如:

strCommand="cmd /c Z:\psexec \\%COMPUTERNAME% /accepteula -s -n 120 " _
    & cmd /c c:\temp\SCRIPT1.bat " & strUserID & ">>" & strRemoteLog
Call errProcess

Run Code Online (Sandbox Code Playgroud)

psexec完成后,您可能希望保存结果.因此,您重命名日志文件,上传它,取消映射您的驱动器,并清理残留文件:

strCommand="cmd /c REN " & strRemoteLog & " SCRIPT1-%COMPUTERNAME%.txt"
Call errProcess
strCommand="cmd /c MOVE /Y c:\temp\SCRIPT1*.txt Z:\scripts\LOGS\"
Call errProcess
strCommand="cmd /c net use * /del /Y"
Call errProcess
strCommand="cmd /c del c:\temp\SCRIPT1*.bat /q"
Call errProcess

Run Code Online (Sandbox Code Playgroud)

你完成了.您已成功映射驱动器,针对远程主机运行例程脚本,并上载其输出.

请注意,此方法也适用于带有UAC的Windows 7和Windows 2008.

这是完整的"示例"集成脚本.随意建议修复,改进等.

On Error Resume Next

 MyShare="\\SHARE1"
 strRemoteLog="c:\temp\MapZ.txt"

' Set remote hostname
strComputer="HOST2"
'strComputer = InputBox("Enter Computer name", _
'"Find PC", strComputer)

' Set remote userid
strUserID="USERID1"
'strComputer = InputBox("Enter userid", _
'"Find User", strComputer)

' Enumerate cimv2 on remote host strComputer
Set objWMIService = GetObject("winmgmts:" & _
"{impersonationLevel=Impersonate}!//" & strComputer & "\root\cimv2")

' Verify remote host exists on domain
If( IsEmpty( objWMIService ) = True ) Then
    WScript.Echo( "OBJECT_NOT_INITIALIZED :: " & strComputer )
    WScript.Quit( OBJECT_NOT_INITIALIZED )
End If

' Prompt for masked password
strPassword=GetPass

' Build and run command to execute on strComputer
strCommand = "cmd /c net use z: " & MyShare & " /user:%USERDOMAIN%\%USERNAME% " & strPassword & ">" & strRemoteLog
Set objProcess = objWMIService.Get("Win32_Process")
Call errProcess

' Copy script(s) from MyShare to HOST2 since psexec cannot run scripts on shared drives
strCommand="cmd /c xcopy Z:\scripts\cleanpclocal.bat c:\temp\ /V /C /I /Q /H /R /Y>>" & strRemoteLog
Call errProcess

' Change directory to c:\temp
'strCommand="cmd /c cd c:\temp>" & strRemoteLog
'Call errProcess

' Start PSEXEC against script
strCommand="cmd /c Z:\psexec \\%COMPUTERNAME% /accepteula -s -n 120 cmd /c c:\temp\cleanpclocal.bat " & strUserID & ">>" & strRemoteLog
Call errProcess

' Rename logfile to include hostname, upload to share,  unmap networked drive, and delete script
strCommand="cmd /c REN " & strRemoteLog & " cleanpc-%COMPUTERNAME%.txt"
Call errProcess
strCommand="cmd /c MOVE /Y c:\temp\clean*.txt Z:\scripts\LOGS\"
Call errProcess
strCommand="cmd /c net use * /del /Y"
Call errProcess
strCommand="cmd /c del c:\temp\clean*.bat /q"
Call errProcess

WScript.Quit





' ***********
' APPENDIX
' Subroutines, functions
' ***********

' **SUBROUTINES**
'strCommand="cmd /c dir z:\scripts\>" & strRemoteLog ' Works to get dir of z:\scripts\

' Function to handle errReturn
Sub errProcess
WScript.Echo "strCommand=" & strCommand
errReturn = objProcess.Create(strCommand, null, null, intProcessID)

If errReturn = 0 Then
    Wscript.Echo "Process was started with a process ID: " & intProcessID
    WScript.Sleep 5000
Else
    Wscript.Echo "Process could not be started due to error: " & errReturn
End If
WScript.Echo

' Error return codes for Create method of the Win32_Process Class
' http://msdn.microsoft.com/en-us/library/windows/desktop/aa389388(v=vs.85).aspx
' 0=Successful Completion
' 2=Access Denied
' 3=Insufficient Privilege
' 8=Unknown failure
' 9=Path Not Found
' 21=Invalid Parameter

End Sub



' **FUNCTIONS**

' Subroutine to get masked password
Function GetPass
' Mask Passwords Using Internet Explorer
' Ensure you follow the technet.com instructions and create file password.htm
' http://blogs.technet.com/b/heyscriptingguy/archive/2005/02/04/how-can-i-mask-passwords-using-an-inputbox.aspx

Set objExplorer = WScript.CreateObject _
    ("InternetExplorer.Application", "IE_")

objExplorer.Navigate "file:///C:\SCRIPTS\password.htm"   
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width = 400
objExplorer.Height = 350 
objExplorer.Left = 300
objExplorer.Top = 200
objExplorer.Visible = 1             

Do While (objExplorer.Document.Body.All.OKClicked.Value = "")
    Wscript.Sleep 250                 
Loop 

strPassword = objExplorer.Document.Body.All.UserPassword.Value
strButton = objExplorer.Document.Body.All.OKClicked.Value
objExplorer.Quit
Wscript.Sleep 250

If strButton = "Cancelled" Then
    Wscript.Quit
'Else
'    Wscript.Echo strPassword
End If

' Return the password
GetPass = strPassword

End Function

Run Code Online (Sandbox Code Playgroud)

归档时间：	14 年，1 月前
查看次数：	16249 次
最近记录：	8 年，10 月前