如何更改现有Windows资源管理器窗口的路径？

Question

我有一个打开的Windows资源管理器窗口的句柄.

如何向其发送命令以便将
示例中的路径更改为:m:\ programs到d:\ programs.

直到现在我正在使用,ShellExecute()但它打开了一个新窗口.这不好(用户体验).

Answer 1

以下BrowseToFolder函数将给定AHandle句柄（如果存在）的Windows资源管理器的现有实例导航到AFolderPath文件夹（如果存在）。如果您不指定第二个参数，则应使用最上面的窗口进行导航（或者至少是文档中声称的那样；现实似乎是现有的最早的窗口）。如果导航成功，则该函数返回True，否则返回False：

uses
  ActiveX, ShlObj, ShellAPI, SHDocVw;

const
  IID_IServiceProvider: TGUID = '{6D5140C1-7436-11CE-8034-00AA006009FA}';
  SID_STopLevelBrowser: TGUID = '{4C96BE40-915C-11CF-99D3-00AA004AE837}';

function GetItemIDListFromPath(const AFolderPath: WideString): PItemIDList;
var
  Count: ULONG;
  Attributes: ULONG;
  ShellFolder: IShellFolder;
begin
  Result := nil;
  if Succeeded(SHGetDesktopFolder(ShellFolder)) then
  begin
    Count := 0;
    if Failed(ShellFolder.ParseDisplayName(0, nil, PWideChar(AFolderPath),
      Count, Result, Attributes))
    then
      Result := nil;
  end;
end;

function BrowseToFolder(const AFolderPath: WideString;
  AHandle: HWND = HWND_TOPMOST): Boolean;
var
  I: Integer;
  WndIface: IDispatch;
  ItemIDList: PItemIDList;
  ShellBrowser: IShellBrowser;
  ShellWindows: IShellWindows;
  WebBrowserApp: IWebBrowserApp;
  ServiceProvider: IServiceProvider;
begin
  Result := False;

  if Succeeded(CoCreateInstance(CLASS_ShellWindows, nil, CLSCTX_LOCAL_SERVER,
    IID_IShellWindows, ShellWindows)) then
  begin
    for I := 0 to ShellWindows.Count - 1 do
    begin
      if (AHandle <> HWND_TOPMOST) then
        WndIface := ShellWindows.Item(VarAsType(I, VT_I4))
      else
        WndIface := ShellWindows.Item(VarAsType(SWC_EXPLORER, VT_UI4));

      if Succeeded(WndIface.QueryInterface(IID_IWebBrowserApp,
        WebBrowserApp)) then
      begin
        if (AHandle = HWND_TOPMOST) or (WebBrowserApp.HWnd = AHandle) then
        begin
          if Succeeded(WebBrowserApp.QueryInterface(IID_IServiceProvider,
            ServiceProvider)) then
          begin
            if Succeeded(ServiceProvider.QueryService(SID_STopLevelBrowser,
              IID_IShellBrowser, ShellBrowser)) then
            begin
              ItemIDList := GetItemIDListFromPath(AFolderPath);
              Result := Succeeded(ShellBrowser.BrowseObject(ItemIDList,
                SBSP_SAMEBROWSER or SBSP_ABSOLUTE));
            end;
          end;
          Break;
        end;
      end;
    end;
  end;
end;

这是示例用法：

procedure TForm1.Button1Click(Sender: TObject);
var
  ExplorerHandle: HWND;
begin
  ExplorerHandle := 123456;

  if not BrowseToFolder('c:\Windows\System32\', ExplorerHandle) then
    ShowMessage('Navigation to a folder failed!')
  else
    ShowMessage('Navigation to a folder succeeded!');
end;

这是一个complete testing project和the blog post我从中已经采取了灵感。