安装tarball的木偶食谱

Question

我想通过使用木偶配方来安装apache maven,但我找不到任何关于如何执行此操作的示例.有人可以帮忙吗？Apache maven打包为tar.gz文件.我正在为木偶使用一个独立的设置.

Answer 1

我使用example42中的这段代码:

define netinstall (
  $url,
  $extracted_dir,
  $destination_dir,
  $owner = "root",
  $group = "root",
  $work_dir = "/var/tmp",
  $extract_command = "tar -zxvf",
  $preextract_command = "",
  $postextract_command = ""
) {
  $source_filename = urlfilename($url)

  if $preextract_command {
      exec {
          "PreExtract $source_filename":
              command => $preextract_command,
              before  => Exec["Extract $source_filename"],
              refreshonly => true,
      }
  }

  exec {
      "Retrieve $url":
          cwd     => "$work_dir",
          command => "wget $url",
          creates => "$work_dir/$source_filename",
          timeout => 3600,
  }

  exec {
      "Extract $source_filename":
          command => "mkdir -p $destination_dir && cd $destination_dir && $extract_command $work_dir/$source_filename",
          unless  => "find $destination_dir | grep $extracted_dir",
          creates => "${destination_dir}/${extracted_dir}",
          require => Exec["Retrieve $url"],
  }

  if $postextract_command {
      exec {
          "PostExtract $source_filename":
              command => $postextract_command,
              cwd => "$destination_dir/$extracted_dir",
              subscribe => Exec["Extract $source_filename"],
              refreshonly => true,
              timeout => 3600,
              require => Exec["Retrieve $url"],    
      }
  }
}

示例用法:

#Install prerequisites
exec { "VPSMonPrerequisites":
    command     => "yum install -y ${vpsmonitor::params::prerequisites}",
    unless      => "rpm -qi ${vpsmonitor::params::prerequisites}",
    timeout     => 3600,
}
#Install tgz from source url
netinstall { vpsmonitor:
    url                 => "${vpsmonitor::params::source_url}",
    extracted_dir       => "${vpsmonitor::params::extracted_dir}",
    destination_dir     => "${vpsmonitor::params::destination_dir}",
    postextract_command => "chown -R user. ${vpsmonitor::params::destination_dir}/${vpsmonitor::params::extracted_dir}",
    require             => [ Exec["VPSMonPrerequisites"], User["user"] ],
}