如何访问 xslt 中的 javascript 变量

Question

如何访问 xslt 中的 javascript 变量

我有以下代码

<xsl:result-document href="output1/output3/index.html" format="html">
 <html>
 <head>
<SCRIPT LANGUAGE="JavaScript">
function getParams() 
{
var idx = document.URL.indexOf('?');
var params = new Array();
if (idx != -1) {
var pairs = document.URL.substring(idx+1, document.URL.length).split('&amp;');
for (var i=0; i&lt;pairs.length; i++) {
nameVal = pairs[i].split('=');
params[nameVal[0]] = nameVal[1];
   }
}
return params;
}
params = getParams();
</SCRIPT>

<SCRIPT LANGUAGE="JavaScript">
val = unescape(params["value"]);
document.write("value = " + val);
</SCRIPT>
</head>

<body>
 <xsl:choose>
    <xsl:when test="a:id=''">
    <xsl:value-of select="a:name"/>
    </xsl:when>
 </xsl:choose>
</body>
</html>
</xsl:result-document>

Run Code Online (Sandbox Code Playgroud)

我想访问 xsl:when' 中的 javascript 变量 'val'。我需要该值以便我可以运行条件。有什么想法 - 怎么做？

Answer 1

pgf*_*aro 1

Saxon-CE是一个在浏览器中运行的 XSLT 2.0 处理器。它被编译为 JavaScript 并提供高水平的 JavaScript 互操作性。JavaScript/DOM 节点、数字、字符串、布尔值和数组（转换为 XSLT 2.0 序列）在 JavaScript/XSLT 界面上相对无缝地工作。

对于您的具体情况，您在 Saxon-CE 中有多种选择；您可以使用ixsl:call()直接调用现有或注入的 JavaScript 函数，也可以使用ixsl:get()检索变量的值。或者，您可以在 XSLT 2.0 中完成整个操作：

[已编辑评论中提到的更正]

XSLT代码

这是作为文本而不是图形包含的相同代码 - 没有格式化

<xsl:transform
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:ixsl="http://saxonica.com/ns/interactiveXSLT"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:f="urn:local-function"
    xmlns:a="urn:source-xml"
    extension-element-prefixes="ixsl"
    version="2.0"
>
    <xsl:template match="/">
        <xsl:variable name="urlparams" select="ixsl:get(
            ixsl:get(ixsl:window(),'location'),
            'search')"
            as="xs:string"/>
        <xsl:variable name ="pairs" select="tokenize(substring($urlparams,2), '&amp;')"
            as="xs:string*"/>
        <xsl:variable name="value" select="f:getValue($pairs)"/>
        <p>value: <xsl:value-of select="$value"/></p>
        
        <xsl:choose>
            <xsl:when test="a:id eq $value">
                <xsl:value-of select="a:name"/>
            </xsl:when>
        </xsl:choose>
    
    </xsl:template>
    
    <xsl:function name="f:getValue" as="xs:string*">
        <xsl:param name="pairs" as="xs:string*"/>
        <xsl:sequence select="for $p in $pairs,
           $v in substring-before($p, '=')
        return
            if ($v eq 'value')
                then substring($p, string-length($v) + 2)
            else ()"/>
    </xsl:function>

</xsl:transform>

Run Code Online (Sandbox Code Playgroud)

为此，您需要使用 Saxon-CE - 该错误表明正在使用另一个不支持此扩展功能的 XSLT 处理器。您使用 Saxon-CE 吗？ (2认同)

归档时间：	13 年，12 月前
查看次数：	6043 次
最近记录：	3 年，6 月前