如何在Racket中下载和解析csv文件？

Question

如何在Racket中下载和解析csv文件？

Answer 1

使用get-pure-port下载的文件,并使用行星库(require (planet neil/csv))解析它.

下面的示例下载并解析一个csv文件,其中包含各种加拉帕戈斯群岛大小的数据以及每个岛屿上发现的物种数量.

#lang racket
(require (planet neil/csv:1:=7) net/url)

(define galapagos-url 
  (string->url
   "http://www.stat.washington.edu/~handcock/536/Data/galapagos.csv"))

(define make-galapagos-csv-reader
  (make-csv-reader-maker
   '((separator-chars              #\,)
     (strip-leading-whitespace?  . #t)
     (strip-trailing-whitespace? . #t))))

(define (all-rows url make-reader)
  (define next-row (make-reader (get-pure-port url)))
  (define (loop)
    (define row (next-row))
    (if (empty? row)
        '()
        (cons row (loop))))
  (loop))

(all-rows galapagos-url make-galapagos-csv-reader)

返回的第一行是:

'(("Island"
   "Observed.species"
   "Native.species"
   "Area(km^2)"
   "Elevation(m)"
   "Distance.nearest.island(km)"
   "Distance.Santa.Cruz(km)"
   "Area.adj.island(km^2)")
  ("Baltra" "58" "23" "25.09" "" "0.6" "0.6" "1.84")
  ("Bartolome" "31" "21" "1.24" "109" "0.6" "26.3" "572.33")
  ("Caldwell" "3" "3" "0.21" "114" "2.8" "58.7" "0.78")

Answer 2

Neil有一个新的库,csv-reading,所以请使用它.

首先,使用raco安装软件包:

raco pkg install csv-reading

要将CSV文件转换为列表,这是一个辅助函数:

(require csv-reading)

(define (csvfile->list filename)
  (call-with-input-file filename
                        csv->list))

要下载CSV文件并转换为列表,请执行以下操作:

(require net/url)
((compose csv->list get-pure-port string->url) "http://example.com")

请参阅此处了解csv-reading库:csv-reading库,它是最新版本(其他答案使用已弃用的库).