如何将数组传递给Perl中的函数？

Question

问题1:

我想将一个数组传递给一个函数.但是在函数中改变了传递的参数.是值吗？

问题2:

#my ($name, $num, @array)= @_;   <=1 )
my $name = shift;                <=2 )
my $num = shift;
my @array = shift;

案例1和案例2有不同的输出.它为什么会发生？

#!/usr/bin/perl
use strict;

my @test1;
push @test1, ['a', 1];
push @test1, ['b', 1];
push @test1, ['c', 1];
push @test1, ['d', 1];
push @test1, ['e', 1];

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out1: $test1[$i][0]  $test1[$i][1]\n";
}

test_func("test_func", 10, @test1);

sub test_func {
    #my ($name, $num, @array)= @_;   <=1)
    my $name = shift;                <=2)
    my $num = shift;
    my @array = shift;

    print "$name\n";
    print "$num\n";

    for (my $i=0; $i< scalar(@test1); $i++) {
        print "$array[$i][0]  $array[$i][1]\n";
    }

    for (my $i=0; $i< scalar(@test1); $i++) {
        if ($array[$i][0] eq 'a') {
            $array[$i][0] = 'z';
        }
    }
    for (my $i=0; $i< scalar(@test1); $i++) {
        print "change: $array[$i][0]  $array[$i][1]\n";
    }
}

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out2: $test1[$i][0]  $test1[$i][1]\n";
}

#

以下是测试输出.

out1: a  1
out1: b  1
out1: c  1
out1: d  1
out1: e  1
test_func
10
a  1
b  1
c  1
d  1
e  1
change: z  1
change: b  1
change: c  1
change: d  1
change: e  1
out2: z  1 <= Why did it change?
out2: b  1
out2: c  1
out2: d  1
out2: e  1

Answer 1

我想将一个数组传递给一个函数[...]有不同的输出.它为什么会发生？

您无法将数组传递给函数 sub.Subs只能将标量列表作为参数.

test_func("test_func", 10, @test1);

是相同的

test_func("test_func", 10, $test1[0], $test1[1], $test1[2], $test1[3], $test1[4]);

您正在创建一个新的数组test_func,当你做

my ($name, $num, @array) = @_;

shift返回第一个元素@_,它必然是标量.@_是一个数组,数组的元素是标量.相当于

my $name  = shift(@_);
my $num   = shift(@_);
my @array = splice(@_);

要将数组传递给子,通常会传递对它的引用.

test_func("test_func", 10, \@test1);

my ($name, $num, $array) = @_;

my $name  = shift;
my $num   = shift;
my $array = shift;

say "@$array";

但是在函数中改变了传递的参数.是值吗？

Perl永远不会超值.它总是通过引用传递.如果更改了任何元素@_,它将更改调用者中的相应参数.

$ perl -E'sub f { $_[0] = "def"; }  my $x = "abc"; f($x); say $x;'
def

但那不是问题.你不要改变任何元素@_.你正在做的是改变由$test[0]和引用的单个数组$array[0].

这就是你在做什么:

my $ref1 = [ 'a', 1 ];  # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes the single array (not $ref1 or $ref2).

它的缩写

my @anon = ( 'a', 1 );
my $ref1 = \@anon;      # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes @anon (not $ref1 or $ref2).

可存储的dclone可用于使一个阵列的'深拷贝’.

my $ref1 = [ 'a', 1 ];
my $ref2 = dclone($ref1);  # clones the reference, the array, 'a' and 1.
$ref1->[0] = 'y';          # Changes the original array
$ref2->[0] = 'z';          # Changes the new array