如何在Ocaml中表示一个简单的有限状态机？

Question

我用C++和Java编写了一些状态机,但从未使用像Ocaml这样的函数式语言

问题是我不知道我是否可以只调整对象语言版本的代码,因为在Ocaml中,记录和变体比类更强大;

所以,我需要一个事件驱动的有限状态机(像UML一样分层),可以轻松配置

在该领域有经验的人可以发布一个简单的样本吗？只是为了避免最常见的陷阱

谢谢 :)

编辑 16/03:没有可变状态可以做到吗？我想以"FSM"的名称正确封装它,我应该选择一个模块还是一个类？

Answer 1

这取决于您如何操作FSM,例如,如果您需要能够存储其状态并在以后继续,或者您只是想立即执行它.在后一种情况下,将它作为一组尾递归函数来实现它是微不足道的.

例如,假设正则表达式C((A|B)*CD)*- 以下相互递归函数是相应FSM的直接实现,它识别匹配此正则表达式的列表(如果我没有犯任何错误:)):

type alphabet = A | B | C | D

let rec s1 = function
  | C :: rest -> s2 rest
  | _ -> false

and s2 = function
  | [] -> true
  | (A | B) :: rest -> s2 rest
  | C :: rest -> s3 rest
  | _ -> false

and s3 = function
  | D :: rest -> s2 rest
  | _ -> false

每个函数恰好对应于自动机的一个状态并实现其转换函数.Apply s1 : alphabet list -> bool将在参数上运行FSM.

PS:请注意这是一个如何展示尾部呼叫优化的优点和优雅的应用程序...

Answer 2

通常,您创建一个与自动机状态相对应的记录,并且您有另一种类型用于触发转换到另一个状态的事件.在状态记录中,您有一个映射,可以为每个事件查找新状态.

假设您的转换由字符串触发:

type event = string

module EventMap = Map.Make(struct
    type t = event
    let compare = compare
  end)

type state = {
  state_info : ...; (* the content of that state, id, comment, etc. *)
  mutable state_transitions : state EventMap.t;
}

let next_state current_state event =
  try
    EventMap.find event current_state.state_transitions
  with Not_found -> current_state

在这里,我认为未知事件保持在同一状态,但您可能在记录中有错误状态...

Answer 3

这里有一个很好的答案,它展示了OCaml在表示有限状态机时的表现力和优雅:

ocaml中的自动机

对于较严重的使用,你可以尝试看看一些有限状态机库一样FSM库在这里.

Answer 4

我最近在OCaml中创建了一个FSM模块,你可以在这里找到它

我对我的FSM实现有一些特殊的要求,这可能会让它看起来不像其他人指出的那样好,但是,我认为你声明FSM本身的方式是好的和声明性的.特殊要求是我需要能够从FSM的声明性描述生成HDL(硬件描述语言)中的代码,此外还能够模拟FSM在OCaml版本中的操作.因此,我需要使用谓词表达式而不是转换函数(否则,我将如何将函数转换为字符串？)因此,主要想要关注那里的FSM模块以及那里的create和eval_fsm函数.

以下是一个用法示例:

(*********************************************************
 * FSM testing *******************************************
*)

(* inputs to the FSM *)
let full         = Var({name ="full"; value  = F});;
let ten_minutes  = Var({name = "ten_minutes"; value = F});;
let empty        = Var({name = "empty"; value = F});;
let five_minutes = Var({name = "five_minutes"; value =F});;


(* T is true,    F is false *)
let _ = 
  assign full         F ;
  assign ten_minutes  F ;
  assign empty        F ;
  assign five_minutes F ;;

(* outputs from the FSM *)
let water_on     = Var({name = "water_on";    value = F});;
let agitate      = Var({name = "agitate";     value = F});;
let drain        = Var({name = "drain"  ;     value = F});;
let start_timer  = Var({name = "start_timer"; value = F});;
let motor_on     = Var({name = "motor_on";    value = F});;
let washed       = Var({name = "washed";    value = F});;
let soap         = Var({name = "soap";        value = F});;

let reset_actions = 
  assign water_on      F;
  assign agitate       F;
  assign drain         F;
  assign start_timer   F;
  assign motor_on      F;;

module WashStates = 
  struct
   type t =  START | FILL | WASH | DRAIN |  RINSE | SPIN | STOP
     deriving(Show, Enum)    
   let start_state = START
  end 

module LogicExp = 
  struct
    type t     = boolean Logic.bexp
    type var_t = boolean Logic.variable
    let eval_exp exp = to_bool (Logic.eval exp)
    let var_to_s     = var_to_s
  end

module WashFSM = FSM(WashStates)(LogicExp) 

open WashStates

(* declare the state table *)
(*   CS,   PREDICATE,               NS,    ACTIONs *)
let my_fsm = [
  (START, Const(T),                 FILL, [(water_on,   T); 
                                           (soap,       T)]);
  (FILL,  Bop(And,full,soap),       WASH, [(water_on,   F);
                                           (agitate,    T);
                                           (washed,     T);
                                           (start_timer,T)]);
  (WASH,  ten_minutes,              DRAIN,[(agitate,    F);
                                           (start_timer,F); 
                                           (empty,      T)]); 
  (DRAIN, Bop(And,empty,soap),      FILL, [(drain,      F); 
                                           (soap,       F);
                                           (water_on,   T)] );
  (FILL,  Bop(And,full,Not(soap)),  RINSE,[(water_on,   F); 
                                           (soap,       F);
                                           (empty,      F);
                                           (agitate,    T)]);
  (RINSE, ten_minutes,              DRAIN, [(agitate,   F);
                                            (empty,     T)] );
  (DRAIN, Bop(And,empty,Not(soap)), SPIN,  [(motor_on,  T);
                                            (start_timer,T)]);
  (SPIN,  five_minutes,             STOP,  [(water_on,  F);
                                            (drain,     F);
                                            (start_timer,F);
                                            (motor_on,  F)]);
  (STOP,  Const(T),                 STOP,  [(motor_on,  F)]);
];; 


let st_table, current_state = WashFSM.create my_fsm in

let _ = assign full T in
let current_state = WashFSM.eval_fsm st_table current_state  in
let _ = assign ten_minutes T in
let current_state = WashFSM.eval_fsm st_table current_state  in
let current_state = WashFSM.eval_fsm st_table current_state  in
let _ = (assign ten_minutes F);(assign empty T) in
let current_state = WashFSM.eval_fsm st_table current_state  in

let _ = assign five_minutes T in
let current_state = WashFSM.eval_fsm st_table current_state  in
let _ = assign five_minutes F in
let _ = assign ten_minutes T in
let current_state = WashFSM.eval_fsm st_table current_state  in
let current_state = WashFSM.eval_fsm st_table current_state  in
let _ = assign five_minutes T in
let _ = WashFSM.eval_fsm st_table current_state  in
(*...and so on...*)

(请原谅";;"结尾 - 我希望能够将此代码剪切并粘贴到REPL中)

这里使用的一些代码可以在我的github上的Logic项目中找到(fsm.ml是该项目的一部分).谓词表达式的计算结果为T或F(真或假).如果为true,则转换从当前状态转换到下一状态. Const T意味着始终过渡.表达式如:

Bop(And, full, soap) 

意味着如果full和soap都是T(true),那么表达式的计算结果为true.