逗号分隔字符串解析XSLT到for-each节点

Question

我有一个输入字符串,其中包含csv值.例如,1,2,3我需要将每个值分开并分配给for-each循环中的目标节点.

我在下面的模板中根据分隔符拆分输入字符串.如何将每个分隔值分配给for-each循环中的目标元素.

<xsl:template name="output-tokens">
<xsl:param name="list"/>
<xsl:param name="delimiter"/>
<xsl:variable name="newlist">
  <xsl:choose>
    <xsl:when test="contains($list, $delimiter)">
      <xsl:value-of select="normalize-space($list)"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:variable>
<xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
<xsl:variable name="remaining"
              select="substring-after($newlist, $delimiter)"/>
<xsl:variable name="count" select="position()"/>
<num>
  <xsl:value-of select="$first"/>
</num>
<xsl:if test="$remaining">
  <xsl:call-template name="output-tokens">
    <xsl:with-param name="list" select="$remaining"/>
    <xsl:with-param name="delimiter">
      <xsl:value-of select="$delimiter"/>
    </xsl:with-param>
  </xsl:call-template>
</xsl:if>
</xsl:template>

输入xml:

<out1:AvailableDates>
<out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

预期产出:

<tns:AvailableDates>
<tns:AvailableDate>15/12/2011</tns:AvailableDate>
<tns:AvailableDate>16/12/2011</tns:AvailableDate>
<tns:AvailableDate>120/12/2011</tns:AvailableDate>
</tns:AvailableDates>

Answer 1

这是一个完整而简短的真正的XSLT 1.0解决方案:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:out1="undefined" xmlns:tns="tns:tns"
  exclude-result-prefixes="out1 tns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="out1:AvailableDate">
  <tns:AvailableDates>
    <xsl:apply-templates/>
  </tns:AvailableDates>
 </xsl:template>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pItemElementName" select="'tns:AvailableDate'"/>
  <xsl:param name="pItemElementNamespace" select="'tns:tns'"/>

    <xsl:if test="string-length($pText) > 0">
     <xsl:variable name="vNextItem" select=
      "substring-before(concat($pText, ','), ',')"/>

      <xsl:element name="{$pItemElementName}"
                   namespace="{$pItemElementNamespace}">
       <xsl:value-of select="$vNextItem"/>
      </xsl:element>

      <xsl:call-template name="split">
        <xsl:with-param name="pText" select=
                       "substring-after($pText, ',')"/>
        <xsl:with-param name="pItemElementName" select="$pItemElementName"/>
        <xsl:with-param name="pItemElementNamespace" select="$pItemElementNamespace"/>
      </xsl:call-template>
    </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的XML文档(更正为格式良好)时:

<out1:AvailableDates xmlns:out1="undefined">
    <out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

产生了想要的正确结果:

<tns:AvailableDates xmlns:tns="tns:tns">
   <tns:AvailableDate>15/12/2011</tns:AvailableDate>
   <tns:AvailableDate>16/12/2011</tns:AvailableDate>
   <tns:AvailableDate>19/12/2011</tns:AvailableDate>
   <tns:AvailableDate>20/12/2011</tns:AvailableDate>
   <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>

Answer 2

使用XSLT 2.0,您可以使用tokenize(string, separator)函数而不是命名模板.

这个xsl:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:tns="http://tnsnamespace">

    <xsl:template match="AvailableDate">
        <tns:AvailableDates>
            <xsl:for-each select="tokenize(current(), ',')">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>
</xsl:stylesheet>

给出以下结果:

<?xml version="1.0" encoding="UTF-8"?>
<tns:AvailableDates xmlns:tns="http://tnsnamespace">
    <tns:AvailableDate>15/12/2011</tns:AvailableDate>
    <tns:AvailableDate>16/12/2011</tns:AvailableDate>
    <tns:AvailableDate>19/12/2011</tns:AvailableDate>
    <tns:AvailableDate>20/12/2011</tns:AvailableDate>
    <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>

更新:

使用Xslt 2.0处理器在向后兼容模式下,模板后面给出了相同的结果:

<xsl:template match="AvailableDate">
    <tns:AvailableDates>
        <xsl:variable name="myValue">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="."/>
                <xsl:with-param name="delimiter" select="','"/>
            </xsl:call-template>
        </xsl:variable>

        <xsl:for-each select="$myValue/node()">
            <tns:AvailableDate>
                <xsl:value-of select="."/>
            </tns:AvailableDate>
        </xsl:for-each>
    </tns:AvailableDates>
</xsl:template>

对于Xslt 1.0 - 简单(使用标准函数)不可能通过变量访问节点 - 请参阅@Dimitre Novatchev回答XSLT 1.0 - 创建节点集并作为参数传递

为此,XSLT 1.0处理器包含扩展功能: node-set(...)

对于Saxon 6.5 node-set()函数在http://icl.com/saxon命名空间中定义

因此,在XSLT 1.0处理器的情况下,解决方案将是:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common"
    xmlns:out1="http://out1namespace"
    xmlns:tns="http://tnsnamespace"
    exclude-result-prefixes="out1 exslt">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="out1:AvailableDate">
        <tns:AvailableDates>
            <xsl:variable name="myValue">
                <xsl:call-template name="output-tokens">
                    <xsl:with-param name="list" select="."/>
                    <xsl:with-param name="delimiter" select="','"/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:for-each select="exslt:node-set($myValue)/node()">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>

    <xsl:template name="output-tokens">
        <xsl:param name="list"/>
        <xsl:param name="delimiter"/>
        <xsl:variable name="newlist">
            <xsl:choose>
                <xsl:when test="contains($list, $delimiter)">
                    <xsl:value-of select="normalize-space($list)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
        <xsl:variable name="remaining"
            select="substring-after($newlist, $delimiter)"/>
        <xsl:variable name="count" select="position()"/>
        <num>
            <xsl:value-of select="$first"/>
        </num>
        <xsl:if test="$remaining">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="$remaining"/>
                <xsl:with-param name="delimiter">
                    <xsl:value-of select="$delimiter"/>
                </xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

感谢@Dimitre Novatchev纠正我和他从变量访问节点集的答案.