Infix for All(叶子)

Question

Infix[] 仅适用于第一级:

Infix[(c a^b)^d]
(*
-> (a^b c) ~Power~ d
*)

因为我想(不要问为什么)将完整的表达式切换为中缀符号,我尝试了类似的东西:

SetAttributes[toInfx, HoldAll];
toInfx[expr_] := Module[{prfx, infx},
  prfx = Level[expr, {0, Infinity}];
  infx = Infix /@ prfx /. {Infix[a_Symbol] -> a, Infix[a_?NumericQ] -> a};
  Fold[ReplaceAll[#1, #2] &, expr, Reverse@Thread[Rule[prfx, infx]]]
  ]
k = toInfx[(c a^b)^d]
(*
-> (c ~Times~ (a ~Power~ b)) ~Power~ d
*)

但这有两个明显的问题,因为

1. (c a^b)^d == a~Power~b~Times~c~Power~d
   所以我得到的并不是有效使用中缀.
2. 它不健壮,并且无法轻松表达,例如 k = toInfx[a/b + ArcTan[a/b]]

是否有一种简单的方法来Infix[]为All(叶子)工作？

Answer 1

这是一种方式:

ClearAll[toInfixAlt];
SetAttributes[toInfixAlt, HoldAll];
toInfixAlt[expr_] :=
 First@MapAll[Infix, HoldForm[expr]] //. 
   Infix[a : _?(Function[s, AtomQ[Unevaluated@s], HoldAll]) | _[_]| _[]] :> a

我用过,HoldForm因为你可能希望代码保持不被评估.这是一个例子:

In[781]:= toInfixAlt[(c a^b)^d/(1/2)]
Out[781]= ((c ~Times~ (a ~Power~ b)) ~Power~ d) ~Times~ (1/((1/2)))

编辑

和,

In[792]:= toInfixAlt[a/b+ArcTan[a/b]]
Out[792]= (a ~Times~ (b ~Power~ (-1))) ~Plus~ ArcTan[a ~Times~ (b ~Power~ (-1))]

结束编辑

至于多余的括号,删除它们比较困难,因为由于各种操作符的优先级,它们确实需要它们,但应该是可能的.

编辑2

为了优先考虑,这是一个尝试:

ClearAll[toInfixAlt];
SetAttributes[toInfixAlt, HoldAll];
toInfixAlt[expr_] := 
  First@MapAll[Infix, HoldForm[expr]] //. 
     Infix[a : _?(Function[s, AtomQ[Unevaluated@s],HoldAll]) | _[_] | _[]] :> a //. 
     {
        Infix[f_[a__, Infix[r : (h_[___])],b___]] /; 
            Precedence[Unevaluated[f]] <= Precedence[Unevaluated[h]] :> Infix[f[a, r, b]],
        Infix[b___,f_[Infix[r : (h_[___])], a__]] /; 
            Precedence[Unevaluated[f]] <= Precedence[Unevaluated[h]] :> Infix[f[b, r, a]]
     };

现在,我得到:

In[963]:= toInfixAlt[a/b+ArcTan[a/b]]
Out[963]= (a b ~Power~ (-1)) ~Plus~ ArcTan[a ~Times~ (1/b)]