冻结Ada任务

Question

我该如何冻结任务？

我的意思是,如果我有任务

task body My_Task is
begin 
  accept Start;
  loop
    Put ("1");
    Put ("2");
    Put ("3");
    ...
    Put ("n");
  end loop;
end My_Task;

有没有办法可以"冻结"当前状态的任务？例如,如果执行完成执行Put ("2");,我该如何冻结它,之后我可以将其转为继续？我想要从任务之外以及从外部开始冻结,命令它继续.

更新

如果我有规范,我可以肯定实施

type State_Type is
  (RUN,
   FROZEN);

task type My_Task (State : State_Type) is
   entry Start;
end My_Task;

身体

task body My_Task is
begin 
  accept Start;
  loop
    Put ("1");
    Put ("2");
    Put ("3");
    ...
    Put ("n");

    loop 
     if State = RUN then exit; end if;
    end loop;
  end loop;
end My_Task;

但事实并非如此,因为我必须等待第n个Put指令行(即,任务实际上不会被冻结,因为内部循环将会运行).

Answer 1

您可以使用"选择性接受"来允许您的任务被外部调用者(另一个任务或主程序)中断.你不能(轻松地)在执行中的任意点中断任务; 相反,任务本身需要确定何时接受入口调用.

所以你可能想要替换你的序列

Put("1");
Put("2");
Put("3");
...
Put("n");

通过Put每次迭代调用一次的循环,每次都select执行一个语句.

这是一个我刚刚聚集在一起的演示程序.计数器每秒递增一次(大约).如果Running为真,则打印计数器值; 否则循环静默进行.主程序每隔3秒调用Pause和Resume.

如果两个条目都没有被调用else,则select语句中的子句会使它继续执行.

with Ada.Text_IO; use Ada.Text_IO;
procedure T is

    task Looper is
        entry Pause;
        entry Resume;
    end Looper;

    task body Looper is
        Running: Boolean := True;
        Count: Integer := 0;
    begin
        loop
            select
                accept Pause do
                    Running := False;
                end;
            or
                accept Resume do
                    Running := True;
                end;
            else
                null;
            end select;
            delay 1.0;
            if Running then
                Put_Line("Running, Count = " & Integer'Image(Count));
            end if;
            Count := Count + 1;
        end loop;
    end Looper;

begin -- T
    loop
        delay 3.0;
        Looper.Pause;
        delay 3.0;
        Looper.Resume;
    end loop;
end T;

可能有比这更优雅的方法.自从我真正使用过Ada以来已经有很长一段时间了.