为什么 ULong > 16 位数字的数学运算会变得不稳定？

Question

我正在开发一个“简单”基数转换器，用于将基数为 10 的 ULong 转换为任何基数的字符串。这里我使用64个字符。用例是缩短存储为字符串的 ULong。

Public Class BaseConverter
    'base64, but any length would work
    Private Shared ReadOnly Characters() As Char = {"0"c, "1"c, "2"c, "3"c, "4"c, "5"c, "6"c, "7"c, "8"c, "9"c,
                                                    "a"c, "b"c, "c"c, "d"c, "e"c, "f"c, "g"c, "h"c, "i"c, "j"c, "k"c, "l"c, "m"c, "n"c, "o"c, "p"c, "q"c, "r"c, "s"c, "t"c, "u"c, "v"c, "w"c, "x"c, "y"c, "z"c,
                                                    "A"c, "B"c, "C"c, "D"c, "E"c, "F"c, "G"c, "H"c, "I"c, "J"c, "K"c, "L"c, "M"c, "N"c, "O"c, "P"c, "Q"c, "R"c, "S"c, "T"c, "U"c, "V"c, "W"c, "X"c, "Y"c, "Z"c,
                                                    "+"c, "-"c}

    Public Shared Function Encode(number As ULong) As String
        Dim buffer = New Text.StringBuilder()
        Dim quotient = number
        Dim remainder As ULong
        Dim base = Convert.ToUInt64(Characters.LongLength)

        Do
            remainder = quotient Mod base
            quotient = quotient \ base
            buffer.Insert(0, Characters(remainder).ToString())
        Loop While quotient <> 0

        Return buffer.ToString()
    End Function

    Public Shared Function Decode(str As String) As ULong
        If String.IsNullOrWhiteSpace(str) Then Return 0

        Dim result As ULong = 0
        Dim base = Convert.ToUInt64(Characters.LongLength)
        Dim nPos As ULong = 0

        For i As Integer = str.Length - 1 To 0 Step - 1
            Dim cPos As Integer = Array.IndexOf(Of Char)(Characters, str(i))
            result += (base ^ nPos) * Convert.ToUInt64(cPos)
            nPos += 1
        Next
        Return result
    End Function
End Class

对于 16 位以内的数字，它可以正常工作，但是当数字有更多位数时，它开始四舍五入很奇怪。

17 位数字导致 8 的跳转，18 位数字导致 32 的跳转，19 位导致 256 的跳转。

例如，42347959784570944周围的这些数字不起作用并导致这些块：

42347959784570939 > 2msPWXX00X > 42347959784570936 ERROR
42347959784570940 > 2msPWXX00Y > 42347959784570944 ERROR
42347959784570941 > 2msPWXX00Z > 42347959784570944 ERROR
42347959784570942 > 2msPWXX00+ > 42347959784570944 ERROR
42347959784570943 > 2msPWXX00- > 42347959784570944 ERROR
42347959784570944 > 2msPWXX010 > 42347959784570944
42347959784570945 > 2msPWXX011 > 42347959784570944 ERROR
42347959784570946 > 2msPWXX012 > 42347959784570944 ERROR
42347959784570947 > 2msPWXX013 > 42347959784570944 ERROR
42347959784570948 > 2msPWXX014 > 42347959784570944 ERROR
42347959784570949 > 2msPWXX015 > 42347959784570952 ERROR

问题一定出在Decode()函数中，因为生成的字符串不同。

我在https://dotnetfiddle.net/7wAGLh上进行了一些测试，但我找不到问题。

Answer 1

指数运算符始终^返回。 这意味着整个表达式被计算并返回为（然后默默地塞进 a 中）。Double
(base ^ nPos) * Convert.ToUInt64(cPos)DoubleULong

这会带来您所观察到的Double不精确性。

Option Strict On始终使用是捕获这些错误的好方法。

如果您知道(base ^ nPos)不会超过最大值ULong（无论如何这似乎是假设），则修复方法是

result += CULng(base ^ nPos) * Convert.ToUInt64(cPos)