Data.Vector.Mutable 字段无法正确写入/设置？：哈斯克尔

Question

我花了好几天的时间来构建一个data具有可变值字段的结构Data.Vector.Mutable

我确认Data.Vector.Mutable它的行为符合我的预期；然而，一旦它被纳入一个结构中，就会以某种方式停止工作，这违背了我的期望。

下面是一个演示代码，它仅具有newVal,getVal并setVal针对结构的可变字段值。

newIO是类型为 的数据结构的构造函数newIO :: a -> A a。

module Main where
import Control.Monad.Primitive (PrimMonad (PrimState))
import qualified Data.Vector.Mutable as M 
------------------------------------ 
data A a = A
  { ioVal :: IO (M.MVector (PrimState IO) a)
  }

newIO :: a -> A a
newIO = \a -> A (newVal a)
------------------------------
newVal :: a -> IO (M.MVector (PrimState IO) a)
newVal = \a -> do
  val <- M.new 1
  M.write val 0 a
  return val

getVal :: A a -> IO a
getVal = \aA -> do
  val <- ioVal aA
  M.read val 0

setVal :: a -> A a -> IO ()
setVal = \a -> \aA -> do
  val <- ioVal aA
  M.write val 0 a
------------------------------
main :: IO ()
main = do
  let ioA = newIO (5 :: Int)
  (getVal ioA) >>= print -- 5
  setVal 10 ioA
  (getVal ioA) >>= print -- 5 ?? expected 10

因此，在这里，为了确认结构的set/get的基本行为，我尝试创建、读取、（重新）写入和（重新）读取字段的可变值；但是，它并没有按照该集应有的效果发挥作用。

代码有什么问题吗？请指教。

Answer 1

Haskell 的一个主要属性是引用透明性：我们总是可以用定义的实体替换它们的定义。现在考虑发布的代码：

main :: IO ()
main = do
  let ioA = newIO (5 :: Int)
  (getVal ioA) >>= print -- 5
  setVal 10 ioA
  (getVal ioA) >>= print -- 5 ?? expected 10

这定义了ioA，所以我们可以用它自己的定义替换它。我们得到：

main :: IO ()
main = do
  (getVal (newIO (5 :: Int))) >>= print -- 5
  setVal 10 (newIO (5 :: Int))
  (getVal (newIO (5 :: Int))) >>= print -- 5 ?? expected 10

现在我们可以看到问题了：我们创建了三个独立的向量。问题是let ioA = ...定义了一个 IO 操作（大致上是一个命令式过程），我们可以稍后多次调用它。但我们不希望这样：我们newIO (5 :: Int)只想被处决一次。

为此，我们必须避免let并使用一元绑定（<-在do块中）。

main :: IO ()
main = do
  ioA <- newIO (5 :: Int)   -- run the action, just once
  (getVal ioA) >>= print
  setVal 10 ioA
  (getVal ioA) >>= print

这将触发一堆类型错误，因为eggetVal不再传递IO操作，而是传递IO操作的结果。但这正是我们想要的，因此我们需要相应地修复类型。

首先从IO这里删除：

data A a = A
  { ioVal :: M.MVector (PrimState IO) a
  }

事实上，我们不想存储生成向量的过程，我们想要存储向量。

因此，我们需要删除 其他一些观点<-。let

getVal :: A a -> IO a
getVal = \aA -> do
  let val = ioVal aA  -- no IO action to run here
  M.read val 0

另外，newIO必须返回一个IO值。

newIO :: a -> IO (A a)
newIO = \a -> fmap A (newVal a)

我想你现在可以弄清楚剩下的事情了。