在以下任何来源中均未找到插件 [id：'io.spring.dependency-management'，版本：'1.0.11.RELEASE']：

Question

大家好，我是 GraalVM 的新手，正在尝试按照指南启动一个 spring 本机项目https://docs.spring.io/spring-native/docs/current/reference/htmlsingle/#getting-started-buildpacks。

当我添加plugins { id 'org.springframework.experimental.aot' version '0.11.0' }到 build.gradle 文件后尝试同步时，它失败并出现错误：

Plugin [id: 'io.spring.dependency-management', version: '1.0.11.RELEASE'] was not found in any of the following sources:

* Try:
Run with --scan to get full insights.

* Exception is:
org.gradle.api.plugins.UnknownPluginException: Plugin [id: 'io.spring.dependency-management', version: '1.0.11.RELEASE'] was not found in any of the following sources:

- Gradle Core Plugins (plugin is not in 'org.gradle' namespace)
- Plugin Repositories (could not resolve plugin artifact 'io.spring.dependency-management:io.spring.dependency-management.gradle.plugin:1.0.11.RELEASE')
Searched in the following repositories:
MavenRepo
maven(https://repo.spring.io/release)

这是我的 build.gradle

plugins {
    id 'org.springframework.boot' version '2.6.1'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
    id 'org.springframework.experimental.aot' version '0.11.0'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

repositories {
    mavenCentral()
    maven { url 'https://repo.spring.io/release' }
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation('org.springframework.boot:spring-boot-starter-test')
}

test {
    useJUnitPlatform()
}

bootBuildImage {
    builder = "paketobuildpacks/builder:tiny"
    environment = [
            "BP_NATIVE_IMAGE" : "true"
    ]
    buildpacks = ["gcr.io/paketo-buildpacks/java-native-image:7.1.0"]
}

和设置.gradle：

pluginManagement {
    repositories {
        // ...
        mavenCentral()
        maven { url 'https://repo.spring.io/release' }
    }
}

rootProject.name = 'demo'

我想知道是否id 'io.spring.dependency-management' version '1.0.11.RELEASE'不兼容id 'org.springframework.experimental.aot' version '0.11.0'

如果有人能帮助我的话，非常感谢！

---

nvm 我自己解决了，这是一个愚蠢的错误，哈哈

我的 settings.gradle 中丢失了gradlePluginPortal()，它应该是

pluginManagement {
    repositories {
        maven { url 'https://repo.spring.io/release' }
        mavenCentral()
        gradlePluginPortal()
    }
}