批处理文件.删除目录中的所有文件和文件夹

Question

我想要一个批处理文件,它将删除我的无线工具包的Cache文件夹中的所有文件夹和文件.

目前我有以下内容:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

这将删除我的RMS目录中的所有.db文件,但是我想删除此目录中的所有内容

你能帮我吗？谢谢.

Answer 1

创建批处理文件

将文本复制到批处理文件中

set folder="C:\test"
cd /d %folder%
for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)

将删除所有文件和文件夹

Answer 2

del *.*而不是del *.db.这将删除一切.

Answer 3

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

这将删除文件夹(和文件夹本身)中的所有内容.

Answer 4

del *.*只会删除文件,但不会删除子目录.要查看目录的内容,可以使用以下脚本:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

Answer 5

从morty346发布的内容中把它放在一起:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

添加快速检查变量中定义的文件夹是否存在,然后将目录更改为该文件夹并删除内容.

Answer 6

您可以使用del和/S标志(告诉它递归所有子目录中的所有文件)来执行此操作:

del /S C:\Path\to\directory\*

也可以使用RD命令.在没有提示的情况下以静默方式递归删除

@RD /S /Q %VAR_PATH%

https://technet.microsoft.com/en-gb/library/bb490990.aspx

Answer 7

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)