如何将 CsvHelper.CsvWriter 与 F# 选项类型一起使用？

Question

我正在尝试使用 .Net CsvHelper 库将 F# 记录集合保存到 csv 文件。问题是选项类型未正确转换为字符串。

#r "nuget: CsvHelper"

open System.IO 
open System.Globalization
open CsvHelper

type Record = { X : string; Y : float option }

let writeString x =
    use writer = new StringWriter()
    use csv = new CsvWriter(writer, CultureInfo.InvariantCulture)
    csv.WriteRecords(x)
    writer.ToString()

[{ X = "hi"; Y = Some 1.00}
 { X = "bye"; Y = None }]
|> writeString

nan我期望此处第二个数据行中的第二个字段为空白值（或 CsvProvider 能够理解的任何其他值）。相反，CsvHelper 会将None值转换为0.

val it : string = "X,Value
hi,1
bye,0
"

我知道这FSharp.Data.CsvProvider可以让我将这个简单的记录转换为CsvFile.Row可以保存的记录。但当您有很多字段时，这是一个糟糕的解决方案，因为很难保持字段的顺序CsvFile.Row（想象一下 50 个浮点字段）。我更喜欢自动转换记录字段的解决方案。

Answer 1

CsvHelper 中似乎没有对 F# 的内置支持，因此您可能必须编写自己的类型转换器来处理选项。这是我快速整理的一个：

open System.IO 
open System.Globalization
open CsvHelper
open CsvHelper.TypeConversion

type OptionConverter<'T>() =
    inherit DefaultTypeConverter()
    override __.ConvertToString(value, row, memberMapData) =
        match value :?> Option<'T> with
            | None -> ""
            | Some x -> base.ConvertToString(x, row, memberMapData)

type Record = { X : string; Y : float option }

let writeString x =
    use writer = new StringWriter()
    use csv = new CsvWriter(writer, CultureInfo.InvariantCulture)
    csv.Context.TypeConverterCache.AddConverter<Option<float>>(OptionConverter<float>())
    csv.WriteRecords(x)
    writer.ToString()

[<EntryPoint>] 
let main _ =
    [{ X = "hi"; Y = Some 1.00}
     { X = "bye"; Y = None }]
        |> writeString
        |> printfn "%s"
    0

输出是：

X,Y
hi,1
bye,

FWIW，有一些 CSV 库更容易从 F# 使用，例如FSharp.Data CSV 提供程序。