Delphi 对程序怪异的引用

Question

在 Delphi 中，您显然可以将整个方法调用链分配给单个变量：

program What;
{$APPTYPE CONSOLE}

type
  TProc = reference to procedure();

  TRecord = record
    procedure MethodOfRecord();
  end;

procedure TRecord.MethodOfRecord();
begin
  WriteLn('MethodOfRecord finished');
end;

function MakeRecord(): TRecord;
begin
  WriteLn('    MakeRecord finished');
end;

var
  proc: TProc;
begin
  proc := MakeRecord().MethodOfRecord;
  proc();
  proc();
  proc();
end.

在这段代码中，我创建了一个 anonymous TRecord，将其方法分配TRecord.MethodOfRecord给 a reference to procedure，然后调用它 3 次。

问题：会MakeRecord被调用多少次？

答案：3次：

    MakeRecord finished
MethodOfRecord finished
    MakeRecord finished
MethodOfRecord finished
    MakeRecord finished
MethodOfRecord finished

每次我打电话时proc，它都会MakeRecord先打电话。这看起来很奇怪。为什么会发生这种情况？我预计它只会被调用一次。是因为匿名吗？当然，如果我给 TRecord 一个名字，它只会被调用一次：

var
  proc: TProc;
  rec: TRecord;
begin
  rec := MakeRecord();
  proc := rec.MethodOfRecord;
  proc();
  proc();
  proc();
end.

这输出：

    MakeRecord finished
MethodOfRecord finished
MethodOfRecord finished
MethodOfRecord finished

有人可以解释这种行为背后的逻辑吗？这是在某处记录的吗？

这是 Embarcadero® Delphi 10.3。

更新：

这不仅适用于reference to procedure()，还适用于任何可以接受参数和返回值的函数，例如使用TProc = reference to function(s: string): string;.

program What;
{$APPTYPE CONSOLE}

uses System.SysUtils;

type
  TProc = reference to function(s: string): string;

  TRecord = record
    FirstHalf: string;
    function Combine(secondHalf: string): string;
  end;

function TRecord.Combine(secondHalf: string): string;
begin
  Result := Format('%s + %s', [FirstHalf, secondHalf]);
  WriteLn(Format('   Combine finished with secondHalf = %s', [secondHalf]));
end;

function MakeRecord(firstHalf: string): TRecord;
begin
  Result.FirstHalf := firstHalf;
  WriteLn(Format('MakeRecord finished with  firstHalf = %s', [firstHalf]));
end;

var
  proc: TProc;
  msg: string;
begin
  proc := MakeRecord(msg).Combine;
  msg := 'A';
  WriteLn(proc('a'));
  msg := 'B';
  WriteLn(proc('b'));
  msg := 'C';
  WriteLn(proc('c'));
end.

这输出：

MakeRecord finished with  firstHalf = A
   Combine finished with secondHalf = a
A + a
MakeRecord finished with  firstHalf = B
   Combine finished with secondHalf = b
B + b
MakeRecord finished with  firstHalf = C
   Combine finished with secondHalf = c
C + c

Answer 1

proc := MakeRecord().MethodOfRecord;

这proc是一个匿名方法，但MethodOfRecord不是，这是一个正常的过程。您可能会预料到编译错误，但编译器会在后台为您做一些工作。它把你的代码变成这样：

proc := 
  procedure 
  begin 
    MakeRecord().MethodOfRecord; 
  end;

现在右手边是一个匿名方法，你可以看到你的程序为什么会这样。

如果不想在每次调用时都创建新记录，则需要为要使用的记录实例声明一个局部变量。