珀尔；如何避免严重嵌套的 foreach 循环

Question

我想循环遍历 12 个字符串，并列出它们的每个组合，例如我缩短了 3 个术语的工作代码：

foreach my $t1 ('a', 0) {
    foreach my $t2 ('b', 0) {
        foreach my $t3 ('c', 0) {
            my @terms = grep {$_ ne '0'} ($t1, $t2, $t3);
            say join ('+', @terms);
        }
    }
}

哪个输出

a+b+c
a+b
a+c
a
b+c
b
c

这是正确的输出。

但是，我意识到foreach循环的深度嵌套并不是好的编码习惯。

我已经在Alternate looping nested foreach 循环中查看了替代方法，但这要求这也非常难看：

my @t1 = ("a", (0) x 132);
my @t2 = ("b", (0) x 132);
my @t3 = ("c", (0) x 132);
my @t4 = ("d", (0) x 132);
my @t5 = ("e", (0) x 132);
my @t6 = ("f", (0) x 132);
my @t7 = ("g", (0) x 132);
my @t8 = ("h", (0) x 132);
my @t9 = ("i", (0) x 132);
my @t10 = ("j", (0) x 132);
my @t11 = ("k", (0) x 132);
my @t12 = ("l", (0) x 132);

my $it = each_array(@t1, @t2, @t3, @t4, @t5, @t6, @t7, @t8, @t9, @t10, @t11, @t12);
while (my ($t1, $t2, $t3, $t4, $t5, $t6, $t7, $t8, $t9, $t10, $t11, $t12) = $it->()) {
    my @terms = grep {$_ ne '0'} ($t1, $t2, $t3, $t4, $t5, $t6, $t7, $t8, $t9, $t10, $t11, $t12);
    say join ('+', @terms);
}

这只是输出空格，似乎没有做我认为each_array应该做的事情。我什至不确定会有 132 次迭代。

如何在没有 foreach 循环深度嵌套的情况下完成这 12 个术语？

Answer 1

您正在寻找非空子集。

当您有任意数量的嵌套循环时，您可以使用Algorithm::Loops的NestedLoops.

use Algorithm::Loops qw( NestedLoops );

my @syms = 'a'..'c';
#my @syms = 'a'..'l';

NestedLoops(
   [ map [ $_, undef ], @syms ],
   sub {
      @_ = grep defined, @_;
      say join "+", @_ if @_;
   }
);

NestedLoops 也可用于生成迭代器。

my $iter = NestedLoops([
   map [ $_, undef ], @syms
]);
while ( my @subset = $iter->() ) {
   @subset = grep defined, @subset;
   say join "+", @subset if @subset;
}

算法::组合学的subsets是一个专门解决这个问题。

use Algorithm::Combinatorics qw( subsets );

my $syms = [ 'a'..'c' ];
#my $syms = [ 'a'..'l' ];

my $iter = subsets($syms);
while ( my $subset = $iter->next() ) {
   say join "+", @$subset if @$subset;
}

感谢@larsen 提出这种方法。

这个问题的解决方案可以简单地通过计数到 2 ^N -1来实现，每个位表示一个符号的存在或不存在。

my @syms = 'a'..'c';
#my @syms = 'a'..'l';

my @masks = map { 1 << $_ } 0..$#syms;

for my $n ( 1 .. 2**@syms-1 ) {
   say join "+", map { $n & $masks[$_] ? $syms[$_] : () } 0..$#syms;
}