是否有一个函数来展平嵌套的元素列表？

Question

如何拼合这样的嵌套列表:

[1, 2, 3, 4] == flatten [[[1,2],[3]],[[4]]]

Answer 1

是的,它concat来自标准序曲,由.给出

concat :: [[a]] -> [a]
concat xss = foldr (++) [] xss

如果你想[[[a]]]变成[a],你必须使用它两次:

Prelude> (concat . concat) [[[1,2],[3]],[[4]]]
[1,2,3,4]

Answer 2

由于没有其他人给出这个,因此可以定义一个函数,该函数将使用MultiParamTypeClasses展平任意深度的列表.我实际上并没有发现它有用,但希望它可以被认为是一个有趣的黑客.我从Oleg的多变量函数实现中得到了这个想法.

{-# LANGUAGE MultiParamTypeClasses, OverlappingInstances, FlexibleInstances #-}

module Flatten where

class Flatten i o where
  flatten :: [i] -> [o]

instance Flatten a a where
  flatten = id

instance Flatten i o => Flatten [i] o where 
  flatten = concatMap flatten

现在,如果你加载它并在ghci中运行:

*Flatten> let g = [1..5]
*Flatten> flatten g :: [Integer]
[1,2,3,4,5]
*Flatten> let h = [[1,2,3],[4,5]]
*Flatten> flatten h :: [Integer]
[1,2,3,4,5]
*Flatten> let i = [[[1,2],[3]],[],[[4,5],[6]]]
*Flatten> :t i
i :: [[[Integer]]]
*Flatten> flatten i :: [Integer]
[1,2,3,4,5,6]

请注意,通常需要提供结果类型注释,否则ghc无法确定在何处停止递归应用flatten类方法.如果你使用的单态类型的函数就足够了.

*Flatten> :t sum
sum :: Num a => [a] -> a
*Flatten> sum $ flatten g

<interactive>:1:7:
    No instance for (Flatten Integer a0)
      arising from a use of `flatten'
    Possible fix: add an instance declaration for (Flatten Integer a0)
    In the second argument of `($)', namely `flatten g'
    In the expression: sum $ flatten g
    In an equation for `it': it = sum $ flatten g
*Flatten> let sumInt = sum :: [Integer] -> Integer
*Flatten> sumInt $ flatten g
15
*Flatten> sumInt $ flatten h
15

Answer 3

正如其他人所指出的那样,concat :: [[a]] -> [a]是您正在寻找的功能,它不能展平任意深度的嵌套列表.您需要多次调用它以将其展平至所需级别.

不过,该操作确实可以推广到其他monad.它被称为join,并具有类型Monad m => m (m a) -> m a.

Prelude Control.Monad> join [[1, 2], [3, 4]]
[1,2,3,4]    
Prelude Control.Monad> join (Just (Just 3))
Just 3
Prelude Control.Monad.Reader> join (+) 21
42

Answer 4

import Data.List
let flatten = intercalate []

flatten $ flatten [[[1,2],[3]],[[4]]]
[1,2,3,4]

Answer 5

正如哈马尔指出的那样,join是一种压制名单的" monadic "方式.您也可以使用do-Notation来轻松拼写多个级别的功能:

flatten xsss = do xss <- xsss
                  xs <- xss
                  x <- xs
                  return x