数据类型数组

Question

出于某些原因，我需要有这样的东西：

DT: array[0..3] of types = (string, integer, double, boolean);

这甚至可能吗？

Answer 1

即使它可以编译，生成的DT[]数组也不会用于任何利润。

你只能使用类似的东西

var v: DT[0]; // this will be a string variable

但这显然毫无意义，因为您特别具有定义自定义类型的能力：

type
  TMyString = type string; 
...
 var
   v: TMyString;

所以替换TMyString为DT[0]，你会得到你所期望的。

如果您希望将DT[]eg 与循环一起使用，例如 use DT[i]，那么我看不到此语法的任何可能用途。

另一方面，我通常做的是：

• 使用variant变量来存储任何类型的值——我想这就是你想要重新发明的；
• 使用枚举元类动态启动给定的类。

首先，variant价值观非常强大：

var v: variant;
begin
  v := 1; // now v holds an integer
  ShowMessage(v); // will be converted to string before display
  if VarIsStr(v) then // false
    ShowMessage('string')
  else if VarIsNumeric(v) then // true
    ShowMessage('number');
  v := 'toto'; // now v holds a string
  ShowMessage(v);
  if VarIsStr(v) then // true
    ShowMessage('string')
  else if VarIsNumeric(v) then // false
    ShowMessage('number');
  v := true;   // now v holds a boolean
  if VarIsStr(v) then // false
    ShowMessage('string')
  else if VarIsNumeric(v) then // false
    ShowMessage('number')
  else if VarIsBool(v) then // true
    ShowMessage('boolean');  
...

对于元类：

type
  TMyClassParent = class
  ...
  end;

  TMyClass1 = class(TMyClassParent)
  ...
  end;
  TMyClass2 = class(TMyClassParent)
  ...
  end;
  TMyClass3 = class(TMyClass1)
  ...
  end;

  // define the meta-class type
  TMyClassParentClass = class of TMyClassParent;
  // define an enumeration
  TMyClasses = (myclass1, myclass2, myclass3);

const
  MYCLASS_NAME: array[TMyClasses] of string = (
     'one', 'two', 'three');
  MYCLASS_CLASS: array[TMyClasses] of TMyClassParentClass = (
    TMyClass1, TMyClass2, TMyClass3);

var
  c: TMyClassParent;
  cc: TMyClasses;
begin
  for cc := low(cc) to high(cc) do
  begin
    writeln('Using ', MYCLASS_CLASS[cc].ClassName, ' for class ', MYCLASS_NAME[cc]);
    c := MYCLASS_CLASS[cc].Create;
    try
      // use Liskov's friendly c instance
    finally
      c.Free;  
    end;
  end;
end.

如果你正确地遵循 Liskov 的替换原则，你可以c: TMyClassParent以抽象的方式使用，因为孩子不会影响父类行为的期望。