excel工作表页脚中的上次保存日期

Question

我使用Excel 2007与一个有很多工作表的工作簿.我需要在上次保存工作表的日期 - 在页脚中.我找到了以下内容:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Dim ws As Worksheet

For Each ws In ThisWorkbook.Worksheets
With ws.PageSetup
.LeftFooter = "Last Save Time: &T"
.RightFooter = "Last Save Date: &D"
End With
Next ws

Set ws = Nothing

End Sub

这会更改每个工作表.我需要它只更改已编辑的工作表(因此每个工作表可以有不同的日期).这甚至可能吗？我应该使用单元格而不是页脚吗？或者我是否必须创建多个工作簿？

谢谢!

Answer 1

正如 Remnant 所建议的，最好的方法是利用该Worksheet_Change活动。这意味着，您需要这个 VBA 代码

Private Sub Worksheet_Change(ByVal Target As Range)
    With Me.PageSetup
        .LeftFooter = "Last Change Time: " & Format(VBA.Time, "hh:mm:ss")
        .RightFooter = "Last Change Date: " & Format(VBA.Date, "dd/mm/yy")
    End With
End Sub

在您的每张工作表中。仅当您更改单元格内容时才会引发此事件，而不是在更改选择时引发，因此它可能是您想要的。

Remnant 还写道，如果您有很多工作表，这将是“设置起来很痛苦”。我认为这取决于你所说的“很多”。对于最多 20~40 个工作表，可以在几分钟内轻松地将上面的代码手动复制到每张工作表中。

如果您已经有一个工作簿和很多（例如，超过 40 张）工作表，那么以编程方式添加代码可能是个好主意。将包含此代码的单独模块添加到您的工作簿中，并运行一次：

Option Explicit
Sub InsertCode()
    Dim VBProj As Object
    Dim VBComp As Object
    Dim CodeMod As Object
    Dim sh As Worksheet
    Dim LineNum As Long

    Set VBProj = ActiveWorkbook.VBProject
    For Each sh In ThisWorkbook.Sheets
        Set VBComp = VBProj.vbcomponents(sh.Name)
        Set CodeMod = VBComp.CodeModule
        With CodeMod
            .DeleteLines 1, .CountOfLines
            LineNum = .CreateEventProc("Change", "Worksheet")
            LineNum = LineNum + 1
            .InsertLines LineNum, "Me.Pagesetup.LeftFooter = ""Last Change Time: "" & Format(VBA.Time, ""hh:mm:ss"")"
            .InsertLines LineNum + 1, "Me.Pagesetup.RightFooter = ""Last Change Date: "" & Format(VBA.Date, ""dd/mm/yy"")"
        End With
    Next
End Sub

这会将上面的“Worksheet_Change”事件添加到每个工作表的代码部分。