OpenGL ES - 在片段着色器中旋转纹理而不失真

Question

我正在使用 Android 的 GPUImage 库对位图应用一些效果。本质上，GPUImage接受位图并使用OpenGL ES，将1 x 1立方体渲染到位图大小的帧缓冲区中。用户可以编写自定义片段着色器来控制输出。

我正在尝试编写一个片段着色器，它在给定旋转角度的情况下旋转位图。这是我到目前为止所拥有的：

varying vec2 textureCoordinate;
uniform sampler2D inputImageTexture;
uniform vec2 inputImageTextureSize;
uniform float angle;

const vec2 HALF = vec2(0.5);

void main()
{
    float aSin = sin(angle);
    float aCos = cos(angle);

    vec2 tc = textureCoordinate;
    tc -= HALF.xy;
    tc *= mat2(aCos, aSin, -aSin, aCos);
    tc += HALF.xy;

    vec3 tex = texture2D(inputImageTexture, tc).rgb;
    gl_FragColor = vec4(tex, 1.0);
}

它可以工作，但显然会扭曲位图（因为 GPUImage 视口设置为将 1 x 1 立方体映射到实际位图大小）。我不知道如何消除扭曲。我应该根据角度和 inputImageTextureSize 应用一些额外的缩放变换，但我未能获得正确的方程。StackOverflow 上的答案实际上都不适合我的情况。请帮忙！

谢谢！

Answer 1

您必须考虑视口（窗口）的长宽比。
如果窗口与图像具有相同的长宽比，则可以通过图像的大小计算长宽比：

float aspect = inputImageTextureSize.x / inputImageTextureSize.y;

在旋转之前按纵横比 ( ) 缩放纹理坐标的 u 分量，并在旋转后* aspect按倒数纵横比 ( ) 缩放：* 1.0/aspect

tc -= HALF.xy;
tc.x *= aspect;
tc *= mat2(aCos, aSin, -aSin, aCos);
tc.x *= 1.0/aspect;
tc += HALF.xy;

为了阐明该行为，可以用矩阵运算来表达：

float aSin = sin(angle);
float aCos = cos(angle);

float aspect = u_resolution.x / u_resolution.y;

mat2 rotMat      = mat2(aCos, -aSin, aSin, aCos);
mat2 scaleMat    = mat2(aspect, 0.0, 0.0, 1.0);
mat2 scaleMatInv = mat2(1.0/aspect, 0.0, 0.0, 1.0);

tc -= HALF.xy;
tc = scaleMatInv * rotMat * scaleMat * tc;
tc += HALF.xy;