在Windows批处理文件中查找文件并按大小排序

Question

我将批处理脚本的命令行参数作为文件名和文件夹的列表.对于每个文件名,我需要打印找到该文件的文件夹的所有子文件夹(该文件的路径).子文件夹名称应按文件大小的降序排序(文件可以在不同的子文件夹中具有各种大小).

到目前为止我已经这样做了,但它不起作用:

::verify if the first parameter is the directory

@echo off
REM check the numbers of parameters
if "%2"=="" goto err1
REM check: is first parameter a directory?
if NOT EXIST %1\NUL goto err2
set d=%1
shift
REM iterate the rest of the parameters


for %%i in %dir  do (
find %dir /name %i > temp

if EXIST du /b temp | cut /f 1 goto err3 
 myvar=TYPE temp
echo "file " %i "is in: "

for %%j in %myvar do
 echo %j

 echo after sort
du /b %myvar | sort /nr       
)

:err1
echo Two parameters are necessary 
goto end

:err2
echo First parameter must be a directory.
goto end

:err3 
echo file does not exist.
goto end

:end

Answer 1

由于学期已经过去很长时间,所以回答这个家庭作业问题,我感到内疚.使用Windows批处理递归打印文件夹和文件是一个封闭的重复问题,讨论分配.

我最初的解决方案非常简单.有一些技巧可以确保它正确处理其中包含特殊字符的路径,但没有什么太花哨的.唯一的另一个技巧是使用空格填充文件大小,以便SORT正常工作.

就像在原始问题中一样,第一个参数应该是文件夹路径(.\工作正常),后续参数表示文件名(通配符可以).

@echo off
setlocal disableDelayedExpansion
set tempfile="%temp%\_mysort%random%.txt"

set "root="
for %%F in (%*) do (
  if not defined root (
    pushd %%F || exit /b
    set root=1
  ) else (
    echo(
    echo %%~nxF
    echo --------------------------------------------
    (
      @echo off
      for /f "eol=: delims=" %%A in ('dir /s /b "%%~nxF"') do (
        set "mypath=%%~dpA"
        set "size=            %%~zA"
        setlocal enableDelayedExpansion
        set "size=!size:~-12!"
        echo !size! !mypath!
        endlocal
      )
    ) >%tempfile%
        sort /r %tempfile%
  )
)
if exist %tempfile% del %tempfile%
if defined root popd

我曾希望通过直接用管道替换重定向和后续排序来排序来避免创建临时文件.但这不起作用.(请参阅我的相关问题: 为什么延迟扩展在管道代码块内部失败？)

我的第一个解决方案效果很好,但根据提供的输入,可能存在重复输出.我决定编写一个删除重复文件报告的版本.

基本前提很简单 - 将所有输出保存到一个临时文件,并将文件名添加到已排序字符串的前面.然后我需要遍历结果,只在文件和/或路径发生变化时打印信息.

最后一个循环是棘手的部分,因为文件名可以包含特殊字符! ^ &,%这可能会导致问题,具体取决于使用的扩展类型.我需要在循环中设置和比较变量,这通常需要延迟扩展.但延迟扩展会导致FOR变量扩展时出现问题!.我可以通过在循环外调用来避免延迟扩展,但随后FOR变量变得不可用.我可以将变量作为参数传递给CALLed例程而不会延迟扩展,但是后来我遇到了% ^和的问题&.我可以用SETLOCAL/ENDLOCAL玩游戏,但是我需要担心在ENDLOCAL屏障上传递值,这需要一个相当复杂的转义过程.这个问题变成了一个很大的恶性循环.

另一个自我约束是我不想将文件和路径输出括在引号中,这意味着我必须使用延迟扩展,FOR变量或转义值.

我发现了一个有趣的解决方案,它利用了FOR变量的一个奇怪特征.

通常,FOR变量的范围严格在循环内.如果在循环外调用,则FOR变量值不再可用.但是,如果您在被调用的过程中发出FOR语句 - 调用者FOR变量将再次可见! 问题解决了!

@echo off
setlocal disableDelayedExpansion
set tempfile="%temp%\_mysort%random%.txt"
if exist %tempfile% del %tempfile%

set "root="
(
  for %%F in (%*) do (
    if not defined root (
      pushd %%F || exit /b
      set root=1
    ) else (
      set "file=%%~nxF"
      for /f "eol=: delims=" %%A in ('dir /s /b "%%~nxF"') do (
        set "mypath=%%~dpA"
        set "size=            %%~zA"
        setlocal enableDelayedExpansion
        set "size=!size:~-12!"
        echo(!file!/!size!/!mypath!
        endlocal
      )
    )
  )
)>%tempfile%

set "file="
set "mypath="
for /f "tokens=1-3 eol=/ delims=/" %%A in ('sort /r %tempfile%') do call :proc

if exist %tempfile% del %tempfile%
if defined root popd
exit /b

:proc
  for %%Z in (1) do (
    if "%file%" neq "%%A" (
      set "file=%%A"
      set "mypath="
      echo(
      echo %%A
       echo --------------------------------------------
    )
  )
  for %%Z in (1) do (
    if "%mypath%" neq "%%C" (
      set "mypath=%%C"
      echo %%B %%C
    )
  )
exit /b