在 Common Lisp 中，什么时候引用对象，什么时候直接通过值访问？

Question

我正在阅读这个问题以尝试深入了解答案。它特别询问了引用传递，所有的答案似乎都表明不支持引用传递。但是，这个答案意味着，虽然可能不支持按引用传递，但确实可以通过引用访问某些值。一个更简单的例子将涉及 cons 单元；我可以将 cons 单元格传递给一个函数，然后将它的 cdr 或 car 更改为我喜欢的任何内容。

最终，我想知道（使用 C# 用语）值类型和引用类型之间是否有一些明确的界限，以及是否有任何方法（比上面引用的答案更方便）将值视为引用 -类型。

Answer 1

没有区别：所有对象在 Lisp 中都是按值传递的（至少在我知道的所有 Lisp 中）。 然而，有些对象是可变的，而 conses 就是这样一种类型。因此，您可以将 cons 单元格传递给过程并在该过程中对其进行变异。因此，重要的考虑是对象是否可变。

特别是这个（Common Lisp）函数总是T作为它的第一个值返回，即使它的第二个值可能不是0它的 car 或 cdr。

(defun cbv (&optional (f #'identity))
  (let ((c (cons 0 0)))
    (let ((cc c))
      (funcall f c)
      (values (eq c cc) c))))

> (cbv (lambda (c)
         (setf (car c) 1
               (cdr c) 2)))
t
(1 . 2)

然而，由于 Common Lisp 有词法作用域、一流的函数和宏，你可以做一些技巧，让它看起来有点像按引用调用：

(defmacro capture-binding (var)
  ;; Construct an object which captures a binding
  `(lambda (&optional (new-val nil new-val-p))
     (when new-val-p
       (setf ,var new-val))
     ,var))

(defun captured-binding-value (cb)
  ;; value of a captured binding
  (funcall cb))

(defun (setf captured-binding-value) (new cb)
  ;; change the value of a captured binding
  (funcall cb new))

(defun cbd (&optional (f #'identity))
  (let ((c (cons 0 0)))
    (let ((cc c))
      (funcall f (capture-binding c))
      (values (eq c cc) c cc))))

现在：

> (cbd (lambda (b)
         (setf (captured-binding-value b) 3)))
nil
3
(0 . 0)

如果你了解它是如何工作的，那么你可能已经了解了 Lisp 中的作用域和宏是如何工作的。

在 Common Lisp 中按值传递对象的普遍性有一个例外，Rainer 在下面的评论中提到了这一点：在某些情况下可能会复制某些原始类型的实例以提高效率。这只会发生在特定类型的实例上，并且发生这种情况的对象总是不可变的。为了处理这种情况，CL 提供了一个相等谓词，eql它与 做同样的事情eq，除了它知道可能以这种方式秘密复制的对象并正确比较它们。

所以，安全的做法是使用eql而不是eq: 因为可以复制的对象总是不可变的，这意味着你永远不会被这个绊倒。

这是一个示例，其中您自然会认为相同的对象结果并非如此。鉴于此定义：

(defun compare (a b)
  (values (eq a b)
          (eql a b)))

然后在我使用的实现中，我发现：

> (compare 1.0d0 1.0d0)
nil
t

所以双精度浮点零不是eq对自己，总是，但它总是eql对自己。并尝试一些看起来应该相同的东西：

> (let ((x 1.0d0)) (compare x x))
t
t

所以在这种情况下，看起来函数调用不是复制对象，而是我从来自读取器的两个不同对象开始。但是，始终允许实现随意​​复制数字，并且可能会使用不同的优化设置来实现。