使用Bound与多个类型变量进行抽象

Question

我一直在试用绑定包 - 你可以尝试使用的一个玩具示例是System F.与包文档中的示例不同,它包含一个由lambda绑定的变量的类型参数,System F将有两个类型参数,一个用于普通变量(由普通的lambda抽象绑定),一个用于类型变量(由类型抽象绑定).

我不太明白如何使用这个包,但是看一下这些例子,我得到的印象是我应该从编写Monad表达式类型的实例开始.然而,我遇到了麻烦,因为我无法想出具体的东西并且"显然是正确的"(即通过检查看起来直观正确).到目前为止我有

{-# LANGUAGE DeriveTraversable #-}
{-# LANGUAGE DeriveFoldable #-}
{-# LANGUAGE DeriveFunctor #-}
{-# LANGUAGE LambdaCase #-}

module SystemF where

import Bound
import Control.Monad
import Data.Bifunctor

-- e ::= x | ?x : ?. e | e1 e2 | ?X. e | e [?]
-- t denotes type variables, e denotes expression variables
data Exp t e
  = Var e
  | Lam (Scope () (Exp t) e)
  | App (Exp t e) (Exp t e)
  | TyLam (Scope () (FlipExp e) t) -- Is this correct?
  | TyApp (Exp t e) (Type t)

newtype FlipExp e t = FlipExp { getExp :: Exp t e }

instance Functor (Exp t) where
  fmap = second

instance Bifunctor Exp where
  bimap f g = \case
    Var e -> Var (g e)
    Lam s -> Lam (bimapInScope f g s)
    App e1 e2 -> App (bimap f g e1) (bimap f g e2)
    TyLam s' -> TyLam (bimapInScope g f s')
    TyApp e t -> TyApp (bimap f g e) (fmap f t)
    where
      bimapInScope f g = Scope . bimap f (second (bimap f g)) . unscope

instance Applicative (Exp t) where
  pure = Var
  (<*>) = ap

instance Monad (Exp t) where
  x >>= f = case x of
    Var v -> f v
    Lam s -> Lam (s >>>= f)
    App e1 e2 -> App (e1 >>= f) (e2 >>= f)
    TyLam s ->
      -- tmp :: Exp (Var () (Exp t a) a
      -- but we need Exp (Var () (Exp t b)) b
      -- just applying >>= inside the first argument 
      -- is insufficient as the outer 'a' won't change
      let tmp = first (second getExp) $ getExp (unscope s)
      in error "How do I implement this?"
    TyApp e t -> TyApp (e >>= f) t

instance Functor (FlipExp e) where
  fmap = second

instance Bifunctor FlipExp where
  bimap f g = FlipExp . bimap g f . getExp

-- ? ::= X | ? -> ? | ? X . ?
data Type t
  = TVar t
  | TFun (Type t) (Type t)
  | TForall (Scope () Type t)
  deriving (Functor, Foldable, Traversable)

instance Applicative Type where
  pure = TVar
  (<*>) = ap

instance Monad Type where
  x >>= f = case x of
    TVar v -> f v
    TFun t1 t2 -> TFun (t1 >>= f) (t2 >>= f)
    TForall s -> TForall (s >>>= f)

1. 是否有可能有monad实例Exp t？如果有,怎么样？
2. Monad实例背后的直觉是什么？对于State/Maybe monad,我发现将它们视为链接计算(就绑定而言)是有用的,而对于像Lists这样的结构,我发现在平坦化方面考虑是有用的(就连接而言) ).但是,我无法为Exp的Monad实例提出任何正确的直觉.绑定是否精确地捕获 - 避免替换？我阅读了这篇文章,但在普通的"De Bruijn指数"部分之后迷了路.

Answer 1

请参阅此处的讨论和@phadej 的bound-extras软件包此处。

要点是类型抽象是一个术语级别的事物（因此是 的变体Expr），需要对Types 进行抽象。PlainScope b f a不适合处理这种情况，因为它的扩展对于这两种情况f (Either b (f a))都是f固定的。您希望外部f是 an Expr，而内部应该是 a Type。这导致了以下概括Scope：

newtype ScopeH b f g a = ScopeH (g (Either b (f a)))
newtype ScopeT b t f a = ScopeT (t f (Either b (f a)))

newtype Expr' a b = Expr' (Expr b a)
data Expr b a
  = V a
  ...
  | TyApp (Expr b a) (Ty b)
  | Forall (ScopeH () (Expr' a) Ty b)
  ...

Expr' a修复了术语变量的 de Bruijn 索引，以便ScopeH构造函数可以引入一个附加类型变量来放入b孔中。