CMake中的set_target_properties是否会覆盖CMAKE_CXX_FLAGS？

Question

在我的CMake项目开始时,我在变量CMAKE_CXX_FLAGS中设置通用编译标志,就像

set(CMAKE_CXX_FLAGS "-W -Wall ${CMAKE_CXX_FLAGS}")

稍后,我需要附加其他特定于配置的编译标志(存储在BUILD_FLAGS中).我可以使用以下命令:

set_target_properties(${TARGET} PROPERTIES COMPILE_FLAGS ${BUILD_FLAGS})

或者我是否必须手动添加CMAKE_CXX_FLAGS:

set_target_properties(${TARGET} PROPERTIES COMPILE_FLAGS "${CMAKE_CXX_FLAGS} ${BUILD_FLAGS}")

防止BUILD_FLAGS覆盖CMAKE_CXX_FLAGS？

Answer 1

使用第一个:

set_target_properties(${TARGET} PROPERTIES COMPILE_FLAGS ${BUILD_FLAGS})

存储在BUILD_FLAGS中的标志在编译TARGET的源时在CMAKE_CXX_FLAGS之后附加.文档暗示了这一点,但我只是试图确保它.

COMPILE_FLAGS

   Additional flags to use when compiling this target's sources. 

   The COMPILE_FLAGS property sets additional compiler flags used to
   build sources within the target.  Use COMPILE_DEFINITIONS to
   pass additional preprocessor definitions.

完整的命令行将相当于:

${CMAKE_CXX_COMPILER} ${CMAKE_CXX_FLAGS} ${COMPILE_FLAGS} -o foo.o -c foo.cc

正如拉蒙所说,你可以随时查询make VERBOSE=1.

Answer 2

^{接受的答案仍然有效,但自2013年以来已经过时.
这个答案基于CMake v2.8.12,v3.3和v3.13的新功能.}

自CMake-2.8.12(2013)

要设置的两个新命令CMAKE_CXX_FLAGS:

• target_compile_options() (对于一个单一的目标)
• add_compile_options() (适用于所有目标)

自cmake-2.8.12以来,上一版本的文档没有太大变化:

• target_compile_options()
• add_compile_options()

在你的情况下你可以使用:

target_compile_options(${TARGET} PRIVATE ${BUILD_FLAGS})

或者只是如果你有一个目标:

add_compile_options(${BUILD_FLAGS})

更多例子

target_compile_options(mylib PRIVATE   -O2) # only internal
target_compile_options(mylib INTERFACE -gl) # only external
target_compile_options(mylib PUBLIC    -g)  # same as PRIVATE + INTERFACE

# multiple targets and flags
target_compile_options(mylib1 mylib2 PRIVATE -Wall -Wextra)

target_compile_options(    mylib PUBLIC -DUSEXX)  # Bad
target_compile_definitions(mylib PUBLIC -DUSEXX)  # OK

add_compile_options(-Wall -Wextra) # for all targets in current directory
add_compile_options(-DUSEXX)       # Bad
add_definitions(-DUSEXX)           # OK

弃用 COMPILE_FLAGS

COMPILE_FLAGS不推荐使用 cmake-3.0文档标志:

COMPILE_FLAGS

编译此目标源时使用的其他标志.

该COMPILE_FLAGS属性设置用于在目标中构建源的其他编译器标志.使用COMPILE_DEFINITIONS通过额外的预处理器定义.

不推荐使用此属性.请改用COMPILE_OPTIONS属性或 target_compile_options命令.

如果您仍想使用set_target_properties(),可以使用COMPILE_OPTIONS而不是COMPILE_FLAGS:

set_target_properties(${TARGET} PROPERTIES COMPILE_OPTIONS ${BUILD_FLAGS})

自CMake-3.3(2015)

安东彼得罗夫建议在ar31的答案中使用生成器表达式.

CMake 生成器表达式适用${BUILD_FLAGS}于:

• C++语言使用$<COMPILE_LANGUAGE:CXX>(也可以是C,CUDA...)
• 使用Clang编译器$<CXX_COMPILER_ID:Clang>
  (也可以GNU用于gcc或MSVC用于Visual C++ ...查看完整列表)
  ($<C_COMPILER_ID:Clang>如果语言是C则使用)
• 以及更多支持的C++特性或编译器版本 ......(参见文档)

在你的情况下你可以使用:

target_compile_options(${TARGET} PRIVATE
          $<$<COMPILE_LANGUAGE:CXX>:${BUILD_FLAGS_FOR_CXX}>
          $<$<COMPILE_LANGUAGE:C>:${BUILD_FLAGS_FOR_C}>)

或关于编译器:

target_compile_options(${TARGET} PRIVATE
          $<$<CXX_COMPILER_ID:Clang>:${BUILD_FLAGS_FOR_CLANG}>
          $<$<CXX_COMPILER_ID:GNU>:${BUILD_FLAGS_FOR_GCC}>
          $<$<CXX_COMPILER_ID:MSVC>:${BUILD_FLAGS_FOR_VISUAL}>)

自CMake-3.13(2018)

target_link_options()正如Craig Scott所提到的,新函数允许将选项传递给链接器.

C和C++文件的不同选项

最好的方法是使用两个不同的目标来区分C文件和C++文件.