使用 IdHttp Indy 连接 SSL 时出错

Question

我在使用 Indy (Delphi) 的 IdHttp 中遇到问题。

我尝试使用 IdHttp 在 Web 服务 SOAP 中发布 XML，但不起作用。返回“使用 SSL 连接时出错。” 在来自 indy 的 IdSSLOpenSSL.Connect@1437 中。

我的代码很简单：

procedure TForm1.Button1Click(Sender: TObject);
var
  vRequest : TStringStream;
  s : String;
begin
  vRequest  := TStringStream.Create((Memo1.Lines.Text));
  try
    IdHTTP1.Host                       := edHost.Text;
    IdHTTP1.Request.ContentLength      := length(Memo1.Lines.Text);
    IdHTTP1.Request.ContentType        := edContentType.Text;
    IdHTTP1.Request.CustomHeaders.Text := 'SOAPAction: "removed for safe"'#13#10;
    IdHTTP1.request.CacheControl       := 'no-cache';
    IdHTTP1.Request.AcceptEncoding     := edAccept.Text;
    IdHTTP1.HTTPOptions                := [hoKeepOrigProtocol];
    IdHTTP1.ProtocolVersion            := pv1_1;

    Memo2.Clear;
    try
      s := IdHTTP1.post(Edit1.Text, vRequest);
      Memo2.Lines.Text := s;
    except
      on e: EIdHTTPProtocolException do begin
        Label1.Caption     := e.Message;
        MEMO2.LINES.TEXT   := e.Message;
      end;
      on e:Exception do begin
        Label1.Caption     := e.Message;
        MEMO2.LINES.TEXT   := e.Message;
      end;
    end;

    requestHeaders.Lines.Text  := IdHTTP1.Request.RawHeaders.Text;
    responseHeaders.Lines.Text := IdHTTP1.Response.RawHeaders.Text;
  finally
    vRequest.Free;
  end;
end;

在 exe 文件夹中包含 libeay32.dll 和 ssleay32.dll。有什么建议吗？

我使用了delphi 5，但在delphi 7 中也是同样的问题。

Answer 1

默认情况下，SSLVersions属性TIdSSLIOHandlerSockOpenSSL设置为仅启用 TLS 1.0 ¹。但许多网站开始逐步淘汰 TLS 1.0，只接受 TLS 1.1+。所以尝试在SSLVersions属性中启用 TLS 1.1 和 TLS 1.2 ，看看它是否有帮助。

^{1：Indy 的问题跟踪器中有一个开放票证，默认情况下也启用 TLS 1.1 和 TLS 1.2。}

附带说明一下，您应该对代码进行一些进一步的调整：

• 不要为TIdHTTP'sHost或ContentLength属性分配任何值。它们由 自动填充TIdHTTP。

• 如果您AcceptEncoding手动设置该属性，请确保不包含deflate或gzip除非您已Compressor分配给TIdHTTP，否则将无法解码压缩响应。AcceptEncoding除非您准备好处理自定义编码，否则您真的不应该分配任何内容。该Compressor手柄deflate/gzip和TIdHTTP将更新AcceptEncoding，如果相应的Compressor分配，以备使用。

• 使用CustomHeaders.Values属性来设置单个标题，而不是CustomHeaders.Text属性。

• 您不需要EIdHTTPProtocolException显式捕获，因为该异常处理程序没有执行更通用的Exception处理程序没有执行的任何额外操作。

• 该RawHeaders属性是TStringList后代，因此使用Lines.Assign(RawHeaders)代替效率更高Lines.Text := RawHeaders.Text。

尝试这个：

procedure TForm1.Button1Click(Sender: TObject);
var
  vRequest : TStringStream;
  s : String;
begin
  IdHTTP1.Request.ContentType := edContentType.Text;
  IdHTTP1.Request.CustomHeaders.Values['SOAPAction'] := 'removed for safe';
  IdHTTP1.Request.CacheControl := 'no-cache';
  IdHTTP1.HTTPOptions := [hoKeepOrigProtocol];
  IdHTTP1.ProtocolVersion := pv1_1;

  Memo2.Clear;
  try
    vRequest := TStringStream.Create(Memo1.Lines.Text);
    try
      s := IdHTTP1.Post(Edit1.Text, vRequest);
    finally
      vRequest.Free;
    end;
    Memo2.Lines.Text := s;
  except
    on e: Exception do begin
      Label1.Caption := e.Message;
      Memo2.Lines.Text := e.Message;
    end;
  end;

  RequestHeaders.Lines.Assign(IdHTTP1.Request.RawHeaders);
  ResponseHeaders.Lines.Assign(IdHTTP1.Response.RawHeaders);
end;