符号微分的递归方案

Question

按照这个优秀系列的术语,让我们(1 + x^2 - 3x)^3用a 表示一个表达式Term Expr,其中数据类型如下:

data Expr a =
    Var
  | Const Int
  | Plus a a
  | Mul a a
  | Pow a Int
  deriving (Functor, Show, Eq)

data Term f = In { out :: f (Term f) }

是否存在适合执行符号区分的递归方案？我觉得这几乎是一个专业的Futumorphism Term Expr,即futu deriveFutu适合的功能deriveFutu:

data CoAttr f a  
  = Automatic a
  | Manual (f (CoAttr f a))

futu :: Functor f => (a -> f (CoAttr f a)) -> a -> Term f  
futu f = In <<< fmap worker <<< f where  
    worker (Automatic a) = futu f a
    worker (Manual g) = In (fmap worker g)

这看起来很不错,除了下划线变量是Terms而不是CoAttrs:

deriveFutu :: Term Expr -> Expr (CoAttr Expr (Term Expr))
deriveFutu (In (Var))      = (Const 1)
deriveFutu (In (Const _))  = (Const 0)
deriveFutu (In (Plus x y)) = (Plus (Automatic x) (Automatic y))
deriveFutu (In (Mul x y))  = (Plus (Manual (Mul (Automatic x) (Manual _y)))
                                   (Manual (Mul (Manual _x) (Automatic y)))
                             )
deriveFutu (In (Pow x c))  = (Mul (Manual (Const c)) (Manual (Mul (Manual (Pow _x (c-1))) (Automatic x))))

没有递归方案的版本如下所示:

derive :: Term Expr -> Term Expr
derive (In (Var))      = In (Const 1)
derive (In (Const _))  = In (Const 0)
derive (In (Plus x y)) = In (Plus (derive x) (derive y))
derive (In (Mul x y))  = In (Plus (In (Mul (derive x) y)) (In (Mul x (derive y))))
derive (In (Pow x c))  = In (Mul (In (Const c)) (In (Mul (In (Pow x (c-1))) (derive x))))

作为扩展到这个问题,是否有用于区分和消除"空"递归方案ExprS,从而作为Plus (Const 0) x中出现的分化的结果-在所述数据在一次通过？

Answer 1

看看产品的差异化规则:

(u v)' = u' v + v' u

您需要了解什么来区分产品？您需要知道子项(u',v')的衍生物以及它们的值(u,v).

这正是paramorphism给你的东西.

para
  :: Functor f
  => (f (b, Term f) -> b)
  -> Term f -> b
para g (In a) = g $ (para g &&& id) <$> a

derivePara :: Term Expr -> Term Expr
derivePara = para $ In . \case
  Var -> Const 1
  Const _ -> Const 0
  Plus x y -> Plus (fst x) (fst y)
  Mul x y -> Plus
    (In $ Mul (fst x) (snd y))
    (In $ Mul (snd x) (fst y))
  Pow x c -> Mul
    (In (Const c))
    (In (Mul
      (In (Pow (snd x) (c-1)))
      (fst x)))

在paramorphism中,fst您可以访问子项的派生,同时snd为您提供术语本身.

作为这个问题的扩展,是否存在一种递归方案,用于区分和消除由于区分而产生的"空"Exprs(例如Plus (Const 0)x) - 一次性传递数据？

是的,它仍然是一种混乱.最简单的方法是拥有智能构造函数,例如

plus :: Term Expr -> Term Expr -> Expr (Term Expr)
plus (In (Const 0)) (In x) = x
plus (In x) (In (Const 0)) = x
plus x y = Plus x y

并在定义代数时使用它们.你也许可以将它表达为某种类型的para-cata融合.