sp_OAGetProperty 返回 NULL，OUT 变量声明为 MAX

Question

我有以下问题：

在一个函数中，我使用 OLE 对象来发出 HTTP 请求。函数声明如下：

function [dbo].[FN_GetRequestHTTP](@url varchar(2048), @reponseType varchar(10) = 'text')
returns @responseTable table
(
    StatusCode nvarchar(32),
    StatusText nvarchar(32),
    ResponseText nvarchar(max),
    SpErrorMessage varchar(max)
) as
begin
    declare @responseText nvarchar(4000);
    declare @ret int;
    declare @status nvarchar(32);
    declare @statusText nvarchar(32);
    declare @spErrorMessages nvarchar(4000);
    declare @token int;

    -- Open the connection
    exec @ret = sp_OACreate 'MSXML2.ServerXMLHTTP', @token out;

    if @ret <> 0
    begin
        insert into @responseTable (spErrorMessage)
        values ('Unable to open HTTP connection');

        return;
    end

    -- Send the request
    exec @ret = sp_OAMethod @token, 'open', null, 'GET', @url, 'false';
    exec @ret = sp_OAMethod @token, 'send', null, null;

    -- Handle the response
    exec @ret = sp_OAGetProperty @token, 'status', @status out;
    exec @ret = sp_OAGetProperty @token, 'statusText', @statusText out;

    if @reponseType = 'binary'
    begin
        declare @binaryResult varbinary(8000);
        exec sp_OAGetProperty @token, 'responseBody', @binaryResult out;

        set @responseText = upper(sys.fn_varbintohexstr(@binaryResult));
    end

    else
        exec sp_OAGetProperty @token, 'responseText', @responseText out

    -- Close the connection
    exec @ret = sp_OADestroy @token;

    if @ret <> 0
    begin
        insert into @responseTable (spErrorMessage)
        values ('Unable to close HTTP connection')

        return;
    end

    insert into @responseTable
    values (@status, @statusText, @responseText, null);

    return;
end

通过这种方式，函数按预期工作：它可以发出 HTTP 请求并以我需要的格式返回指定的信息。

当我声明declare @responseText nvarchar(4000);没有固定长度的变量时，问题就来了。我需要它declare @responseText nvarchar(max);和变量declare @binaryResult varbinary(8000);as declare @binaryResult varbinary(max);，因为我可以收到更长的响应。

当声明为 时max，返回的exec sp_OAGetProperty @token, 'responseText', @responseText out值为NULL，即使我在使用固定值 (4000) 时得到了正确的结果。

我可以遵循哪些变通方法来完成我所寻求的，为什么会发生这种情况sp_OAGetProperty？因为我创建了一个虚拟程序如下：

create procedure SP_ToDeleteAfterTest (@temp varchar(50) out)
as
begin
    set @temp = 'Testing';

    print 'Done'
end

并像这样执行它：

declare @dunno varchar(max)
exec dbo.SP_ToDeleteAfterTest @dunno out

select @dunno

它确实工作正常。

是因为程序有限制sp_OAGetProperty吗？

编辑

按照评论部分给出的建议，这里是使用存储过程实现所需行为：

create procedure [dbo].[SP_GetRequestHTTP](@url varchar(2048), @reponseType varchar(10) = 'text')
as
begin
    declare @responseTable table
    (
        StatusCode nvarchar(32),
        StatusText nvarchar(32),
        ResponseText nvarchar(max),
        SpErrorMessage varchar(max)
    );

    declare @responseText table(content nvarchar(max));
    declare @ret int;
    declare @status nvarchar(32);
    declare @statusText nvarchar(32);
    declare @spErrorMessages nvarchar(4000);
    declare @token int;

    -- Open the connection
    exec @ret = sp_OACreate 'MSXML2.ServerXMLHTTP', @token out;

    if @ret <> 0
    begin
        insert into @responseTable (spErrorMessage)
        values ('Unable to open HTTP connection');
        
        select * from @responseTable;

        return;
    end

    -- Send the request
    exec @ret = sp_OAMethod @token, 'open', null, 'GET', @url, 'false';
    exec @ret = sp_OAMethod @token, 'send', null, null;

    -- Handle the response
    exec @ret = sp_OAGetProperty @token, 'status', @status out;
    exec @ret = sp_OAGetProperty @token, 'statusText', @statusText out;

    if @reponseType = 'binary'
    begin
        declare @binaryResult table(content varbinary(max));
        insert into @binaryResult exec sp_OAGetProperty @token, 'responseBody';
        
        insert into @responseText select top 1 sys.fn_varbintohexstr(content) from @binaryResult;
    end

    else
        insert into @responseText exec sp_OAGetProperty @token, 'responseText'

    -- Close the connection
    exec @ret = sp_OADestroy @token;

    if @ret <> 0
    begin
        insert into @responseTable (spErrorMessage)
        values ('Unable to close HTTP connection')
        
        select * from @responseTable;

        return;
    end

    insert into @responseTable
    values (@status, @statusText, (select top 1 * from @responseText), null);
    
    select * from @responseTable;

    return;
end

Answer 1

如果您需要获得 XML 格式的响应，您应该这样做：

declare @Result int
declare @xml table(Content xml)

INSERT INTO @xml(Content)
EXEC @Result = sp_OAGetProperty @token, 'responseXML.xml'--, @responseText OUT

select * from @xml

代替

exec sp_OAGetProperty @token, 'responseText', @responseText out

按照此链接：https : //social.msdn.microsoft.com/Forums/sqlserver/en-US/ac224833-1ffa-4008-880c-ce8f4d442110/trying-to-obtain-xml-data-from-url-via- sql?forum=sqlxml