Emacs:如何绑定两次敲击的键？

Question

我正在使用Emacs(23),我将C-.键组合绑定到一个函数:

(global-set-key (kbd "C-.") 'myfunction)

是否可以快速"双击"键？例如,我想myfunction在.快速键入两次时调用一个函数.

Answer 1

内置没有任何内容,但您可以使用此代码.自定义变量dc-single-click-cmd并dc-double-click-cmd成为所需的命令.

注意:这会引入一些延迟,b/c代码需要等待一段时间来确定事件是单击还是双击.

(defvar dc-single-click-cmd 'dc-example-single-click)
(defvar dc-double-click-cmd 'dc-example-double-click)
(defvar dc-click-timer nil
  "Pending single-click event.")
(defun dc-example-single-click ()
  (interactive)
  (message "A single click just happened."))
(defun dc-example-double-click ()
  (interactive)
  (message "Wait!  I meant double click."))
(defun dc-click-cmd ()
  "Either kick off a single click, or a double click."
  (interactive)
  (if dc-click-timer
      (progn
        (cancel-timer dc-click-timer)
        (setq dc-click-timer nil)
        (call-interactively dc-double-click-cmd))
    (setq dc-click-timer (run-at-time (when double-click-time 
                                            (/ 1000.0 double-click-time))
                                      nil
                                      'dc-call-single-click))))
(defun dc-call-single-click ()
  "spawn the single click"
  (setq dc-click-timer nil)
  (call-interactively dc-single-click-cmd))