将数组与 Cypher (Neo4j) 结合起来

Question

当我有一个看起来像这样的字符串时：

"app-server/src/test/java/de/something/"

我如何获得任何可能的组合，例如：

app-server/, app-server/src, app-server/src/test, ....

显然我可以用“/”将其分割，然后我就有了一个零件数组。我还可以手动附加所有这些，然后过滤null

...
WITH split(package.path,'/')[..size(split(package.path,'/'))-1]
WITH pathParts,
pathParts[0] AS p01,
pathParts[0] + '/' + pathParts[1] AS p02,
pathParts[0] + '/' + pathParts[1] + '/' + pathParts[2] AS p03,
...

替代：

WITH pathParts[0] AS p01,
reduce(s = pathParts[0], x IN pathParts[1..2] | s + '/' + x) + '/' AS p02,
reduce(s = pathParts[0], x IN pathParts[1..3] | s + '/' + x) + '/' AS p03,
reduce(s = pathParts[0], x IN pathParts[1..4] | s + '/' + x) + '/' AS p04,
...

但这些都是可怕的解决方案。

---

我还想从所有这些中创建父子关系：

(childPackage:Package)-[:HAS_PARENT]->(parentPackage:Package)

例如(app-server/src)-[:HAS_PARENT]->(app-server/)

Answer 1

有必要分割字符串，从数组中删除空元素，并遍历每个元素，同时连接所有前面的元素：

WITH "app-server/src/test/java/de/something/" AS path
WITH FILTER(p in SPLIT(path, "/") WHERE SIZE(p) > 0) AS pathParts
UNWIND RANGE(0, SIZE(pathParts)-1) AS i
RETURN REDUCE(acc = "", p IN pathParts[0..i+1] | acc + p + '/') AS pathPart

并且第二次链接它们不会有问题：

WITH "app-server/src/test/java/de/something/" AS path
WITH FILTER(p in SPLIT(path, "/") WHERE SIZE(p) > 0) AS pathParts
UNWIND RANGE(0, SIZE(pathParts)-1) AS i
WITH collect(REDUCE(acc = "", p IN pathParts[0..i+1] | acc + p + '/')) AS pathParts

UNWIND RANGE(1, SIZE(pathParts)-1) AS i
  MERGE (P1:Package {path: pathParts[i-1]})
  MERGE (P2:Package {path: pathParts[i]})
  MERGE (P2)-[r:hasParent]->(P1)
RETURN P1, r, P2