Jenkins：从全局函数设置环境变量

Question

我有一个多分支管道项目，在SCM中带有脚本化的Jenkinsfile。我想通过共享的全局函数在管道中设置环境变量。我共享的全局函数如下所示：

#!/usr/bin/groovy

def call(String envName = 'staging') {

  def json = libraryResource 'env-config.yaml'
  def config = readYaml text: json
  def envObj = config.environments.find{it.name == envName}
  environment {
    PROJECT = ${envObj.project}
    ARTIFACTS_REPOSITORY = ${envObj.artifacts_repository}
    DOCKER_REGISTRY_PREFIX = ${envObj.docker_registry_prefix}
  }
  println "${envObj}"
}

但是在我的Jenkinsfile中，我看不到这些设置：

timestamps {
  withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'xxx', usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
    node('klm') {
      try {
        def revisionTag
        loadEnvConfig('staging')
        println "project=${env.PROJECT}, repo=${env.ARTIFACTS_REPOSITORY}"
        ...

env.PROJECT并且env.ARTIFACTS_REPOSITORY均为null。如果我envObj从函数返回并在管道中打印属性，则可以看到它们。是否可以通过我的函数设置环境变量？

编辑：我刚刚意识到我无法在多分支管道的Jenkinsfile中设置任何环境变量。例如，这两种模式都不起作用

timestamps {
  withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'xxx', usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
    node('klm') {
      try {
        environment {
          FOO = "bar"
        }
        println "project=${env.FOO}"
        ...

timestamps {
  withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'xxx', usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
    node('klm') {
      try {
        withEnv(["FOO=BAR"]) {
        println "project=${env.FOO}"
        ...

Answer 1

我不完全确定是什么environment以及为什么它不会为您失败。PROJECT = ${envObj.project}不是有效的 Groovy，因此该块不会被执行。看起来您正在尝试将environment指令用于声明性管道，但是，您正在使用脚本化管道。由于共享库和声明性管道的限制，以下选项仅对脚本化管道有效。

在您当前的代码中，您没有修改任何全局脚本变量或返回要在其他步骤中使用的值，因此它们不会产生任何影响。根据您想要呈现给消费者的 API，您有几种不同的方法。

第一个选项是只修改env全局变量：

env.PROJECT = envObj.project
env.ARTIFACTS_REPOSITORY = envObj.artifacts_repository
env.DOCKER_REGISTRY_PREFIX = envObj.docker_registry_prefix

这些将修改env脚本中其他任何地方都可用的全局状态（除非它们被覆盖或删除）。

另一种选择是使用现有withEnv步骤编写方法并允许消费者提供Closure主体。这是我将函数从loadEnvConfigto重命名的示例withEnvConfig：

def call(String envName = 'staging', Closure body) {
  // Previous code... 
  withEnv([
      "PROJECT=${envObj.project}",
      "ARTIFACTS_REPOSITORY=${envObj.artifacts_repository}",
      "DOCKER_REGISTRY_PREFIX=${envObj.docker_registry_prefix}",
  ]) {
    body()
  }
}

Jenkinsfile

withEnvConfig('staging') {
  println "In block project=${env.PROJECT}, repo=${env.ARTIFACTS_REPOSITORY}"
}
println "Out of block project=${env.PROJECT}, repo=${env.ARTIFACTS_REPOSITORY}"

在主体内部，它们被设置为 的值withEnv。在块之外，它们被重置。

我更喜欢这种模式而不是修改全局状态。