awk 中 $0 = $0 是什么意思？

Question

在浏览一段代码时，我看到了以下命令：

grep "r" temp | awk '{FS=","; $0=$0} { print $1,$3}'

临时文件包含以下模式：

 1. r,1,5
 2. r,4,5
 3. ...

我无法理解$0=$0awk 命令中的语句是什么意思。

谁能解释一下是什么意思？

Answer 1

当您执行$1=$1（或对字段进行任何其他分配）时，它会导致记录重新编译，其中 $0 被重建，每个 FS 被替换为 OFS，但它不会改变 NF（除非$1以前没有，然后 NF 将从 0 更改为 1）或重新评估以任何其他方式记录。

当您这样做时$0=$0，会导致字段拆分，其中 NF、$1、$2 等将根据 FS 的当前值重新填充，但它不会将 FS 更改为 OFS 或以任何其他方式修改 $0。

看：

$ echo 'a-b-c' |
    awk -F'-+' -v OFS='-' '
        function p() { printf "%d) %d: $0=%s, $2=%s\n", ++c,NF,$0,$2 }
        { p(); $2=""; p(); $1=$1; p(); $0=$0; p(); $1=$1; p() }
    '
1) 3: $0=a-b-c, $2=b
2) 3: $0=a--c, $2=
3) 3: $0=a--c, $2=
4) 2: $0=a--c, $2=c
5) 2: $0=a-c, $2=c

请注意，即使将 $2 设置为 null 会导致 2 个连续的-s 并且 FS of-+意味着 2 -s 是单个分隔符，但它们不会被如此对待，直到$0=$0导致记录被重新拆分为字段，如输出所示第四步。

您拥有的代码：

awk '{FS=","; $0=$0}'

正在$0=$0用作解决以下事实的问题：在读取第一条记录并将其拆分为字段之后，才设置 FS：

$ printf 'a,b\nc,d\n' | awk '{print NF, $1}'
1 a,b
1 c,d

$ printf 'a,b\nc,d\n' | awk '{FS=","; print NF, $1}'
1 a,b
2 c

$ printf 'a,b\nc,d\n' | awk '{FS=","; $0=$0; print NF, $1}'
2 a
2 c

当然，正确的解决方案是简单地设置 FS BEFORE 读取第一条记录：

$ printf 'a,b\nc,d\n' | awk -F, '{print NF, $1}'
2 a
2 c

要明确 - 将任何值分配给 $0 会导致字段拆分，它不会导致记录重新编译，而将任何值分配给任何字段（$1 等）会导致记录重新编译但不会导致字段拆分：

$ echo 'a-b-c' | awk -F'-+' -v OFS='#' '{$2=$2}1'
a#b#c
$ echo 'a-b-c' | awk -F'-+' -v OFS='#' '{$0=$0}1'
a-b-c