Pascal - 查找元素是否存在于集合中

Question

我有这样的代码：

program Project1;
uses crt;
type alph=set of 'A'..'Z';
var mn:alph;

begin
  clrscr;
  if ('A' in mn) then writeln( 'Yes');
  readln;
end.   

它不打印任何内容，并且引发一些问题： project1.lpr(11,14)警告：变量“mn”似乎没有初始化 我不明白为什么，有什么问题吗？

Answer 1

宣言

type
  Alpha = set of 'A'..'Z';

只是说这Alpha是一种允许包含零个或多个介于A和之间的字母的类型Z。这并不意味着该类型的变量自动包含该集合的每个元素；它只是意味着变量将由该范围内的一组字符组成。

var
  mn: Alpha;                // Uninitialized variable that can contain 
                            // characters between 'A'..'Z'.
begin
  mn := ['A'..'Z'];         // Valid set of every member
  mn := ['A', 'C', 'X'];    // Valid set of three members

编译器正确地告诉您您尚未为 分配任何值mn，因此您正在使用未初始化的变量。

顺便说一句，大多数 Pascal 方言中的标准约定是在类型前面加上 aT以表明它是一种类型。因此，考虑到这一点，这是您发布的代码的工作版本，其中包含更正。

program Project1;

uses 
  crt;

type 
  TAlpha=set of 'A'..'Z';

var 
  mn: TAlpha;
begin
  clrscr;
  mn := ['A'..'Z'];
  if ('A' in mn) then
    Writeln('A is in mn');
  {
    My preference to the if statement above - prints true or false
    depending on whether the character is in the set, so you get output
    either way.
  }
  WriteLn('A in mn: ', ('A' in mn));
  Readln;
end.   

要解决您的其他问题（来自下面的评论）：

要检查字符串以查看所有字符是否都是数字（'0'..'9'），您可以执行以下操作：

function IsNumeric(const str: string): Boolean;
var
  i: Integer;
begin
  Result := True;
  for i := 1 to Length(str) do
    if not (str[i] in ['0'..'9']) then
      Result := False;
end;