从地图中删除零值？

Question

我有一个Clojure映射,可能包含nil的值,我正在尝试编写一个函数来删除它们,但没有太大成功(我是新手).

例如:

(def record {:a 1 :b 2 :c nil})
(merge (for [[k v] record :when (not (nil? v))] {k v}))

这导致了一系列地图,这不是我对合并的期望:

({:a 1} {:b 2})

我想拥有:

{:a 1, :b 2}

Answer 1

your for list comprehension返回一个LIST of maps,因此你需要将这个列表作为可选参数应用于merge函数:

user> (apply merge (for [[k v] record :when (not (nil? v))] {k v}))
{:b 2, :a 1}      

通过将地图过滤为序列并连接到地图中,可以获得更简洁的解决方案:

user> (into {} (filter second record))
{:a 1, :b 2}  

不要删除错误值:

user> (into {} (remove (comp nil? second) record))
{:a 1, :b false}  

使用dissoc允许持久数据共享而不是创建一个全新的地图:

user> (apply dissoc                                                                                            
       record                                                                                                  
       (for [[k v] record :when (nil? v)] k))
{:a 1, :b 2}  

Answer 2

这是一个适用于嵌套地图的方法:

(defn remove-nils
  [m]
  (let [f (fn [[k v]] (when v [k v]))]
    (postwalk (fn [x] (if (map? x) (into {} (map f x)) x)) m)))

Answer 3

你可以把它压成地图:

(into {} (remove (fn [[k v]] (nil? v)) {:a 1 :b 2 :c nil}))
=> {:a 1 :b 2}

Answer 4

Jürgen Hötzel 解决方案改进以修复 nil/false 问题

(into {} (filter #(not (nil? (val %))) {:a true :b false :c nil}))

@thnetos 解决方案的较短版本

(into {} (remove #(nil? (val %)) {:a true :b false :c nil}))

Answer 5

@ Eelco回答的一个变种:

(defn remove-nils [m]
  (let [f (fn [x]
            (if (map? x)
              (let [kvs (filter (comp not nil? second) x)]
                (if (empty? kvs) nil (into {} kvs)))
              x))]
    (clojure.walk/postwalk f m)))

至于@ broma0的观点,它消除了任何空地图.

user> (def m {:a nil, :b 1, :c {:z 4, :y 5, :x nil}, :d {:w nil, :v nil}})
user> (remove-nils m)
{:b 1, :c {:z 4, :y 5}}
user> (remove-nils {})
nil