如何使用 Windows“findstr”命令搜索字符串的精确匹配？

Question

如何使用Windows命令搜索字符串的精确匹配findstr？例如：我只需要找到与字符串完全匹配的内容store，而不是 stored,storeday等。

以下命令返回所有字符串store、stored和storeday：

findstr /l /s /i /m /c:"store" "c:\test\*.txt"

完整脚本：

set "manifest_folder=C:\Calc_scripts*.*"
set "file_list=C:\Search_results\Search_Input.txt"
set "outputfile=C:\Search_results\Search_results.txt"
(for /f "usebackq delims=" %%a in ("%file_list%") do (
    set "found="
    for /f "delims=" %%b in ('findstr /r /s /i /m /c:"%%a" "%manifest_folder%"') do (
        echo %%a is found in %%~nxb
        set "found=1"
    )
    if not defined found (
        echo %%a is not found
    )
))> "%outputFile%" 

Answer 1

根据findstr /?帮助，\<and\>表示单词边界——请参阅以下摘录：

Regular expression quick reference:
  .        Wildcard: any character
  *        Repeat: zero or more occurrences of previous character or class
  ^        Line position: beginning of line
  $        Line position: end of line
  [class]  Character class: any one character in set
  [^class] Inverse class: any one character not in set
  [x-y]    Range: any characters within the specified range
  \x       Escape: literal use of metacharacter x
  \<xyz    Word position: beginning of word
  xyz\>    Word position: end of word

因此，您需要findstr像这样更改命令行：

findstr /r /s /i /m /c:"\<store\>" "c:\test\*.txt"

因此，在完整的脚本中，它应该如下所示：

findstr /r /s /i /m /c:"\<%%a\>" "%manifest_folder%"