替换变量中的"%"

Question

非常简单的问题,还没有解决问题:

C:\> Set var=^%test^%
C:\> Echo %var%
%test%

C:\> Echo %var:^%=-%
%test%

C:\> Why is this not producing -test-?

我尝试加倍并取出胡萝卜(^)但收效甚微.任何建议(或解决方案)赞赏.

莫娜

Answer 1

%使用SET搜索和替换替换的唯一方法是使用延迟扩展.%以一种让你使用正常扩展的方式逃脱是不可能的.

%批处理与命令提示符的规则不同.

在批处理脚本中,%通过加倍来逃避:

@echo off
setlocal enableDelayedExpansion
set "var=%%test%%"
set var
set "var=!var:%%=-!"
set var

--OUTPUT--

var=%test%
var=-test-

从命令提示符,实际上是不可能逃脱的%.如果括在引号内的文本不等于变量名,则百分比保留在原位.此外,未配对的百分比也留在原地.以下代码假定变量test不存在:

C:\test>cmd /v:on
Microsoft Windows [Version 6.1.7601]
Copyright (c) 2009 Microsoft Corporation.  All rights reserved.

C:\test>set "var=%test%"

C:\test>set var
var=%test%

C:\test>set "var=!var:%=-!"

C:\test>set var
var=-test-

C:\test>

如果变量test确实存在,那么您可以使用以下内容设置初始var值:

c:\test>set "var=%^test%"
var=%test%

插入符号"逃脱"下​​一个字符,因此它被消耗,留下正确的值.它可以放在百分比内的任何位置.但代码假定变量^test不存在.如果确实如此,那么它只会扩展该值,如下所示:

C:\test>set "^test=Hello world"

C:\test>set ^^
^test=Hello world

C:\test>set "var=%^test%"

C:\test>set var
var=Hello world

C:\test>