如何通过批处理文件并行读取两个文本文件？

Question

是否有一种简单且性能良好的方法可以逐行读取两个(甚至更多)文本文件？所以要有一个循环,在每次迭代中读取每个文本文件的一行.

for /F给出多个文件的循环不能使用,因为这会一个接一个地读取文件.嵌套的这样的循环当然也没有意义.

Answer 1

诀窍是使用标准输入 重定向 <(另见本网站使用未定义句柄)(3至9)为文件读取整个代码块,命令set /P块中的实际读取一行,并0<&在不确定的把手重定向到STDIN的set /P,从而对于相应的行读取.

这是一个如何工作的例子:

假设有以下两个文本文件names.txt......:

Black
Blue
Green
Aqua
Red
Purple
Yellow
White
Grey
Brown

......和values.txt...:

0
1
2
3
4
5
6
7

...目标是逐行组合以实现此文件,names=values.txt...:

Black=0
Blue=1
Green=2
Aqua=3
Red=4
Purple=5
Yellow=6
White=7

......以下代码完成了(参见所有解释性注释rem):

@echo off
setlocal EnableExtensions EnableDelayedExpansion

rem // Define constants here:
set "FILE1=names.txt"
set "FILE2=values.txt"
set "RET=names=values.txt" & rem // (none to output to console)
if not defined RET set "RET=con"

rem /* Count number of lines of 1st file (2nd file is not checked);
rem    this is necessary to know when to stop reading: */
for /F %%C in ('^< "%FILE1%" find /C /V ""') do set "NUM1=%%C"

rem /* Here input redirection is used, each file gets its individual
rem    (undefined) handle (that is not used by the system) which is later
rem    redirected to handle `0`, `STDIN`, in the parenthesised block;
rem    so the 1st file data stream is redirected to handle `4` and the
rem    2nd file to handle `3`; within the block, as soon as a line is read
rem    by `set /P` from a data stream, the respective handle is redirected
rem    back to `0`, `STDIN`, where `set /P` expects its input data: */
4< "%FILE1%" 3< "%FILE2%" > "%RET%" (
     rem // Loop through the number of lines of the 1st file:
     for /L %%I in (1,1,%NUM1%) do (
         set "LINE1=" & rem /* (clear variable to maintain empty lines;
                        rem     `set /P` does not change variable value
                        rem     in case nothing is entered/redirected) */
         rem // Change handle of 1st file back to `STDIN` and read line:
         0<&4 set /P "LINE1="
         set "LINE2=" & rem // (clear variable to maintain empty lines)
         rem // Change handle of 2nd file back to `STDIN` and read line:
         0<&3 set /P "LINE2="
         rem /* Return combined pair of lines (only if line of 2nd file is
         rem    not empty as `set /P` sets `ErrorLevel` on empty input): */
         if not ErrorLevel 1 echo(!LINE1!=!LINE2!
     )
)

endlocal
exit /B