Haskell - 使用aeson生成JSON会给出不正确的字段顺序

Question

我正在尝试将数据类型编码为JSON:

{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE RecordWildCards #-}

import Data.Aeson

data Trend = Trend
            { period :: String
            , africa :: String
            , americas :: String
            , asia :: String
            } deriving Show

instance ToJSON Trend where
  toJSON Trend{..} = 
    object [ "Period"    .= period
           , "Africa"    .= africa
           , "Americas"  .= americas
           , "Asia"      .= asia
           ]

test = Trend {period = "2013", africa = "1", americas = "2", asia = "3"}

这使:

?: encode test
?: "{\"Asia\":\"3\",\"Period\":\"2013\",\"Africa\":\"1\",\"Americas\":\"2\"}"

我不明白为什么生成的JSON没有与我的数据类型相同的字段.

我期待输出为{期间,非洲,美洲,亚洲},我得到{亚洲,期间,非洲,美洲)

我理解,在传递信息时,顺序并不重要,但我很好奇为什么会发生这种情况.

Answer 1

您可以使用toEncoding自那以后可用的方法aeson-0.10(aeson-0.11尽管可能,但如果可能的话).在这种情况下,您可以更好地控制生成的结构:

instance ToJSON Trend where
  toJSON Trend{..} = 
    object [ "Period"    .= period
           , "Africa"    .= africa
           , "Americas"  .= americas
           , "Asia"      .= asia
           ]

  toEncoding Trend {..} =
    pairs $ "Period"   .= period
         <> "Africa"   .= africa
         <> "Americas" .= americas
         <> "Asia"     .= asia 

或者,如果这很简单,值得使用Generic推导

instance ToJSON Trend where
    toJSON = genericToJSON defaultOptions { fieldLabelModifier = capitaliseFirst }
      where
        capitaliseFirst (x:xs) = toUpper x : xs
        capitaliseFirst []     = []

Answer 2

发生这种情况的原因是因为 Aeson 对象只是一个 HashMap，当 aeson 将 HashMap 转换为文本时，它只是按照 HashMap 返回的顺序序列化键值对 - 这可能与顺序无关钥匙被插入。