如何在Perl中将undef值打印为零？

Question

我正在使用AoA在Perl中构建一个计数矩阵:my @aoa = ()然后$aoa[$i][$j]++在需要增加特定单元格时调用.由于某些单元格根本没有增加,所以它们被保留undef(这些相当于0计数).

我想从矩阵中打印一些行,但是我得到了undef单元格的错误(我只想将其打印为零).我该怎么办？

Answer 1

使用defined带有条件运算符(?:).

#!/usr/bin/perl

use strict;
use warnings;

my @matrix;

for my $i (0 .. 3) {
    for my $j (0 .. 3) {
        if (rand > .5) {
            $matrix[$i][$j]++;
        }
    }
}

for my $aref (@matrix) {
    print join(", ", map { defined() ? $_ : 0 } @{$aref}[0 .. 3]), "\n"
}

如果您使用的是Perl 5.10或更高版本,则可以使用defined-或operator(//).

#!/usr/bin/perl

use 5.012;
use warnings;

my @matrix;

for my $i (0 .. 3) {
    for my $j (0 .. 3) {
        if (rand > .5) {
            $matrix[$i][$j]++;
        }
    }
}

for my $aref (@matrix) {
    print join(", ", map { $_ // 0 } @{$aref}[0 .. 3]), "\n"
}

Answer 2

经典:

print defined $aoa[$i][$j] ? $aoa[$i][$j] : 0;

现代Perl(5.10或更高版本):

print $aoa[$i][$j] // 0;

这是更简洁和Perlish,不得不说.

或者,在打印前运行矩阵,替换undef为0.

use strict;
use warnings;

my @aoa = ();

$aoa[1][1] = 1;
$aoa[0][2] = 1;
$aoa[2][1] = 1;

for my $i (0..2)
{
    print join ",", map { $_ // 0 } @{$aoa[$i]}[0..2], "\n";
}