代码在哪里可以更有效地检查输入字符是否为元音？

Question

该装配项目读取按键并以特定颜色输出它们。当按下一个元音时，它会改变文本的颜色，直到按下另一个元音为止，直到 ESC按下为止。颜色具有一定的模式，这就是为什么sub colorCode, 8当它到达循环结束时。我只是想让它更有效率。我尝试将所有比较语句放入一行，但没有成功。

INCLUDE        Macros.inc
INCLUDE     Irvine32.inc
INCLUDELIB  Irvine32.lib
.386
.STACK 4096
ExitProcess PROTO, dwExitCode:DWORD

.DATA
key       BYTE ?     
colorCode BYTE 5
max       BYTE 13

.CODE
main PROC

FindKey:
mov EAX, 50
call Delay

call ReadKey 
jz FindKey

MOV key, AL 
     cmp key, 75h
     JE UP
     CMP key, 6Fh
     JE UP
     CMP key, 69h
     JE UP
     CMP key, 65h
     JE UP
     CMP key, 61h
     JE UP
     CMP key, 55h
     JE UP
     CMP key, 4Fh
     JE UP
     CMP key, 49h
     JE UP
     CMP key, 45h
     JE UP
     CMP key, 41h
     JE UP
     CMP dx,VK_ESCAPE
     JE OVER

     COLOR:   
          MOVZX EAX, (black * 16) + colorCode
          CALL SetTextColor 
          MOV AL, key
          call WriteChar
          jmp FindKey

          UP: 
               CMP colorCode, 13
               JE RESET
               INC colorCode
               jmp COLOR
               
               RESET:
                    sub colorCode, 8
                    jmp COLOR    
               
     OVER:
     CALL Crlf
     INVOKE ExitProcess, 0
     
main ENDP
END main

Answer 1

如果您对高效的 x86 代码感兴趣，请参阅x86标签 wiki中的链接。有很多好东西，尤其是。阿格纳·福格的指南。

你有keyin AL，但你的cmp指令都使用内存操作数。有一个特殊的操作码cmp al, imm8，因此cmp al, 75h只有一个 2 字节指令。使用绝对位移来寻址key会产生更长的指令。另外，cmp mem,imm不能通过条件跳转进行宏融合。每个insn都需要装载端口。

代码的其余部分看起来很可疑，就像它使用了太多内存操作数，并且缩进很奇怪。（UP看起来像是块的一部分COLOR，但实际上 的末尾有一个无条件跳转COLOR，所以它不会落入UP。）

当然，一长串cmp/je远非最佳，因为所有je目标都是相同的。您不需要弄清楚哪个键实际匹配。

您可以用于此类检查的一种策略是查看是否al在正确的范围内，然后将其用作位图的索引。

编译器使用此策略（Godbolt 编译器资源管理器）来处理这样的一个switch或多个条件if。这就是为什么我们大多数时候使用编译器而不是手动编写汇编：它们知道很多巧妙的技巧，并且可以在适用的地方应用它们。我们得到1<<c了开关，但if实际上是用 GCC 编译的bt。（不过，GCC9 有一个回归，其中开关编译为跳转表。）

请参阅我对另一个 ASCII 问题的回答，了解无符号比较技巧 ( ) 的解释ja .non_alphabetic和高效循环的示例。

    MOV   [key], AL    ; store for later use

    or    al,  20h     ; lowercase (assuming an alphabetic character)
    sub   al, 'a'      ; turn the ascii encoding into an index into the alphabet
    cmp   al, 'z'
    ja  .non_alphabetic

    mov   ecx, (1<<('a'-'a')) | (1<<('e'-a')) | (1<<('i'-a')) | (1<<('o'-a')) | (1<<('u'-a'))   ; might be good to pull this constant out and use an EQU to define it
    ; movzx eax, al    ; unneeded except for possible performance issues on old Intel CPUs (P6 family partial-register stuff).
    bt    ecx, eax      ; test for the letter being set in the bitmap
    jc  UP              ; jump iff al was a vowel
.non_alphabetic:
    CMP dx,VK_ESCAPE    ; this test could be first.
    JE OVER

或者，如果您想计算元音，请使用adc edx, 0或 来将 CF 添加到寄存器，而不是分支。

(bt屏蔽其输入，仅使用低位作为“移位计数”，因此您实际上并不需要movzx。但是，如果您确实需要避免旧 Intel CPU 上的部分寄存器停顿（在 Sandybridge 之前），请使用movzx edx, al代替movzx eax, al。这将在较新的 Intel CPU 上对性能的影响较小：mov-elimination 仅适用于不同的寄存器。但它仍然会为前端花费额外的 uop。）

这显着减少了指令和分支，因此它使用了更少的分支预测器条目。

不要将常量保留在内存中，因为bt:bt mem,reg很慢，因为疯狂的 CISC 语义，如果位索引高于操作数大小，它可以访问不同的地址。bt它仅在与寄存器第一个操作数一起使用时屏蔽位索引。

另一种方法bt是if(mask & 1 << (key - 'a'))：

    movzx ecx, al      ; avoid partial-reg stall or false dep on ecx that you could get with mov ecx,eax or mov cl,ca respectively
    mov   eax, 1
    shl   eax, cl      ; eax has a single set bit, at the index
    test  eax, 1<<('a'-'a') | 1<<('e'-a') | 1<<('i'-a') | 1<<('o'-a') | 1<<('u'-a')
    jnz  .vowel

即使test/jnz可以宏熔断，这也是更多的 uops，因为在 Intel Sandbridge 系列 CPU 上可变计数移位为 3 uops。（同样，疯狂的 CISC 语义会减慢速度）。

或者右移蒙版而不是创建1<<c. 您甚至可以通过test al,1将掩码右移 1 位来安排跳过 a ，这样您想要分支的位就会被移入CF。shr但在 Nehalem 及更早的版本上，读取可变计数移位的标志结果会导致前端停止，直到移位从后端退出，而在 SnB 系列上，可变计数移位仍然为 3 uops。

由于评论正在讨论 SSE：

    ; broadcast the key to all positions of an xmm vector, and do a packed-compare against a constant
    ; assuming  AL is already zero-extended into EAX
    imul    eax, eax, 0x01010101    ; broadcast AL to EAX
    movd    xmm0, eax
    pshufd  xmm0, xmm0, 0    ; broadcast the low 32b element to all four 32b elements
    pcmpeqb xmm0, [vowels]   ; byte elements where key matches the mask are set to -1, others to 0
    pmovmskb eax, xmm0
    test    eax,eax
    jnz   .vowel


section .rodata:
  align 16
  vowels: db 'a','A', 'e','E'
          db 'i','I', 'o','O'
          db 'u','U', 'a','a'
    times 4 db 'a'            ; filler out to 16 bytes avoiding false-positives

使用字节广播（SSSE3pshufb或 AVX2 vpbroadcastb）而不是双字广播 ( pshufd) 将避免imul. 或者在广播之前使用or eax,0x20，这样我们就不需要每个元音的大写和小写版本，只需小写即可。然后我们就可以用movd++或类似的东西punpcklbw来广播。pshufd

这需要从内存中加载一个常量，而不是可以有效地成为指令流中的立即数的 32 位位图，因此即使它只有一个分支，这可能也不是那么好。（请记住，位图版本需要在非字母上分支，然后在元音上分支）。